Re^3: Weather warnings from www.meteoalarm.eu

[wfsp]

Ok, from looking at the link we can simplify things enourmously.

The data we are after are in cells with class col1 or col2. We can loop over those and extract what we need. You will need to tweak as appropriate but hopefully it will give you the idea.

#! /usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

# meteoalarm.html is the source from the website
open my $fh, q{<}, q{meteoalarm.html}
  or die qq{cant open file to read: $!\n};
  
my $content = do{local $/; <$fh>};
my $mp      = Meteoalarm::Parser->new($content);

my $data = $mp->parse;
print Dumper $data;

package Meteoalarm::Parser;

use HTML::TreeBuilder;
use Data::Dumper;
  
sub new {
  my $class   = shift;
  my $content = shift;
  
  my $p = HTML::TreeBuilder->new_from_content($content);
  my $self = {
    parser => $p,
  };
  bless($self, $class);

  return $self;
}

sub parse {
  my $self = shift;
  my $p = $self->{parser};
  
  my (%data);
  
  my @cells = $p->look_down(_tag => q{td}, class => qr/^col[12]$/);
  for my $cell (@cells){
    my $div = $cell->look_down(_tag => q{div});
    my $id  = $div->id;
    my $alt = $div->attr(q{alt});
    my $img = $div->look_down(_tag => q{img});
    my $src = $img?$img->attr(q{src}):q{};

    $data{$id}{fullname} = $alt;
    $data{$id}{warning} = $src;
  }

  return \%data;

}

output (extract)

$VAR1 = {
          'UK' => {
                    'warning' => '',
                    'fullname' => 'United Kingdom'
                  },
          'CY' => {
                    'warning' => '',
                    'fullname' => 'Cyprus'
                  },
          'IE' => {
                    'warning' => 'Bilder/wf/wf_23.jpg',
                    'fullname' => 'Ireland'
                  },
          'IS' => {
                    'warning' => '',
                    'fullname' => 'Iceland'
                  },
          'NL' => {
                    'warning' => '',
                    'fullname' => 'Netherlands'
                  },
          'BE' => {
                    'warning' => '',
                    'fullname' => 'Belgium'
                  },
          'AT' => {
                    'warning' => 'Bilder/wf/wf_23.jpg',
                    'fullname' => 'Austria'
                  },
        };