Find First character of each word in a string

[kevyt]

I am embarrassed to ask such a simple question but I haven't coded much in the last few years and I forgot a few things. I would like to abbreviate a string such as "Internal Computing Department" to ICD. Can you help? I looked for the source code for ucfirst and I did not find anything helpful. I assume I could use a regular expression with a ^ to get the first Char and then | to get chars after a space. Thanks

[GrandFather]

A Perlish version might look something like:

#!/usr/bin/perl
use strict;
use warnings;

my $str = "Internal Computing Department";

print join '', map {uc substr $_, 0, 1} split ' ', $str;

Prints:

ICD

[LanX]

  DB<1> $str="Internal Computing Department"
 
  DB<2> print $str=~m/\b(\w)/g
ICD

UPDATE

nota bene, the regex returned a list not a string!

if you want to uppercase it try uc after joining.

  DB<15> $abbr= uc join "","internal computing department" =~ m/\b(\w)
+/g
 
  DB<16> print $abbr 
ICD

[AnomalousMonk]

But:

  DB<3> print 'my cardio workout' =~ m/\b\w/g;
mcw

Maybe:

  DB<4> print map uc, 'my cardio workout' =~ m/\b\w/g;
MCW

Update: Oops: LanX beat me to the punch.

[kevyt]

Thanks

[sweetblood]

Why not try it yourself and then post your results and your code. Then mention problems that you encounter and errors.

[kevyt]

This works but I dont like it.

$str = 'my cardio workout';

@s = split (/\s/,$str);

foreach (@s){
  my $new_str = substr ($_,0,1);
  $new_str = ucfirst ($new_str);
  $ab .= $new_str;
}

print "AB is $ab\n";

[AnomalousMonk]

If that's the way things are, then maybe:

>perl -wMstrict -le
"my $str = 'eternal corruption defilement';
 ;;
 $str =~ s{ \b ([[:alpha:]]) [[:lower:]]* \s* }{\U$1}xmsg;
 ;;
 print qq{'$str'};
"
'ECD'

Update: Removed an unnecessary level of capture grouping in regex above. Also:  [[:lower:]]* might be better as  [[:alpha:]]* instead.

Update: Or even:

>perl -wMstrict -le
"my $str = 'eternal corruption defilement';
 ;;
 $str =~ s{ (\b [[:alpha:]]+ \s*) }{ uc substr $1, 0, 1 }xmsge;
 ;;
 print qq{'$str'};
"
'ECD'

[AnomalousMonk]

One possible approach:

>perl -wMstrict -le
"my $str = 'Internal Computing Department';
 ;;
 $str =~ s{ [^[:upper:]] }{}xmsg;
 ;;
 print qq{'$str'};
"
'ICD'

Update: Beyond that, maybe try what sweetblood suggests?

[ahmad]

There are more than one way to do it, here are some I can think of:

my $str = 'Internal Computing Department';
my $res = join '' , map {(split //,$_)[0]} split /\s/, $str;
# OR 
my $res = join '' , map { substr $_, 0 , 1 } split /\s/, $str;
# OR 
my $res;
$res .= $1 while ( $str=~m/(\S)\S+/g );

print $res;

[biohisham]

Backreferencing is just another way to go

$string = "Internal Computing Department";
$string =~ s/(\w)\w*/$1\./g;
print $string ;

#OUTPUT
I. C. D.

[locked_user sundialsvc4]

perl -e 'my $foo="Internal computing\n department."; while ($foo =~ /(\w+)/g) {print substr($1, 0,1)."\n";}'

prints:
I
c
d


Note that the /g qualifier is critical.   (If this modifier is omitted, the program will loop endlessly, printing “I.”)   Also review the meanings of the /s, /p, and /m qualifiers, and of the “?” (“non-greedy”) symbol in the pattern string.   Ponder this:   “pos($foo) = undef;.”

The answer is:   “regular expressions.”
Now then, what’s the question?

[phenom]

Another one liner way:

perl -e 'print uc substr( $_, 0, 1 ) for split(/\s+/, shift())' "Inter
+nal Computing Department"