Read Every n elements from Array

[vetrivel]

Hai ,
How to read every 3 elements from array . I have one way for doing this . Could you tell me any other best way to achieve this .

use Data::Dumper;

$test = [ "1" , "2" ,"3" , "4" ,"5" ,"6" ,"7" , "8" ,"9" ,"10" 
];

while( @$test )
{
        @new_Array  = splice( @$test , 0 , 3 ) ;
        print Dumper( \@new_Array ) ;
}

[davido]

I'm interpreting the language of your question to mean read every third element, starting with the first one. That's one situation where a good old "c-style loop" comes in handy:

use strict;
use warnings;
use feature qw/say/;

my @array = qw/0 1 2 3 4 5 6 7 8 9 10 11 12/;

for ( my $idx = 0; $idx < @array; $idx += 3 ) {
    say $array[$idx];
}

perlsyn discusses the various loop types. Your splice method is destructive to the original array, and requires that a new array be set up to accommodate the elements you've selected. The method I demonstrated leaves the original array untouched. If you actually want a new array, you could set one up and push the elements into it within the loop.

Update: You may be asking to read three elements at a time, if I read the language of your question a different way. It's possible to read three elements at a time by just using offsets within the loop, and this would still be non-destructive to your original array.

[LanX]

well splice is destructive, you could alternatively use array slices:

print @arr[$idx..$idx+2]; 
$idx+=3;

or

print @arr[$idx++,$idx++,$idx++];

[ikegami]

In general, reading and writing to a variable in the same statement can lead to problems. It's not a problem here, but that's not obvious at a glance. For example, that code has undefined behaviour in C. My compiler happens to get it "wrong":

$ cat a.c
#include <stdio.h>

int main() {
   int i = 0;
   printf("%d %d %d\n", i++, i++, i++);
   return 0;
}

$ gcc -Wall -o a a.c && a
a.c: In function ‘main’:
a.c:5: warning: operation on ‘i’ may be undefined
a.c:5: warning: operation on ‘i’ may be undefined
2 1 0

It's simpler just to avoid the issue.

[Eliya]

There's nothing wrong with using splice (unless you want the operation to be non-destructive, which you haven't specified).

Another solution would be List::MoreUtils's natatime.  The example in the docs does more or less exactly the same that your code is doing.

[ikegami]

What kind of improvement are you looking for? That looks like a perfectly fine solution. How could it be any simpler?

while (@a) {
   my @group = splice(@a, 0, 3);
   ...
}

for my $i (0..@a/3-1) {
   my @group = @a[$i*3..$i*3+2];
   ...
}

for (my $i=0; $i<@a; $i+=3) {
   my @group = @a[$i..$i+2];
   ...
}

use List::MoreUtils qw( natatime );

my $i = natatime(3, @a);
while (my @group = $it->()) {
   ...
}

[hbm]

Perhaps shortest?

$test  = [ "1" , "2" ,"3" , "4" ,"5" ,"6" ,"7" , "8" ,"9" ,"10" ];

@new_Array=grep++$i%3<1,@$test;

Oops!

[ikegami]

That doesn't do the same thing at all. The OP grabs three at a time. That grabs every third.

[doubledecker]

What is he trying to do with @new_Array as he is creating new array everytime.

OP, Do you have any idea what are you trying to achieve here.