(Hopefully) simple sorting question

[qwerty155]

Hi,

My first question here, thanks in advance for any help you can give me. I'm looking to re-sort a text string (easily split to an array if req'd) that is currently in this format:

$string = "(x1,x1)(x2,y2)........(xn,yn)"

..and sorted by the x co-ordinate, then by y. How an I reorder the string by y co-ordinate first, then by x (without swapping the x & y round within the brackets - or at least swapping back if need be)?

Many thanks

[Corion]

This is a FAQ. See perldoc -q sort or perlfaq4 on How do I sort an array by (anything)?.

[AnomalousMonk]

$string = "(x1,x1)(x2,y2)........(xn,yn)"

A real, sortable string together with its expected sorted output form would have been helpful, both to give the monks something to work with and to clarify the problem. (The apparently erroneous  (x1,x1) first term also doesn't help.)

... sorted by the x co-ordinate, then by y. ... reorder the string by y co-ordinate first, then by x ...

I'm confused by this as to whether you want to sort "by x then by y", or "by y then by x". I will assume the former.

... sorted by the x co-ordinate ...

This suggests to me a Update: ascending numeric sort.

Given these assumptions, here's an example of the sort of thing explained in Corion's link.

>perl -wMstrict -le
"my $u =
   '(x1,y9)(x11,y8)(x1,y7)(x11,y6)(x2,y5)(x22,y4)(x2,y3)(x22,y2)';
 ;;
 my $s =
   join  '',
   map   { $_->[0] }
   sort  { $a->[1][0] <=> $b->[1][0] || $a->[1][1] <=> $b->[1][1] }
   map   { [ $_, [ $_ =~ m{\d+}xmsg ]] }
   split m{ (?<= \)) (?= \() }xms,
   $u
   ;
 ;;
 print qq{'$s'};
"
'(x1,y7)(x1,y9)(x2,y3)(x2,y5)(x11,y6)(x11,y8)(x22,y2)(x22,y4)'

Note: The original string must be split into an array because sort only works on arrays.

Update: Here's a version that will be significantly faster if you're sorting lotsa strings or very long strings. See A Fresh Look at Efficient Perl Sorting for a discussion.

>perl -wMstrict -le
"my $u =
   '(x1,y9)(x11,y8)(x1,y7)(x11,y6)(x2,y5)(x22,y4)(x2,y3)(x22,y2)';
 ;;
 use constant WIDTH => 10;
 my $s =
   join  '',
   map   { substr $_, WIDTH+WIDTH }
   sort
   map   { sprintf '%0*4$d%0*4$d%s', m{\d+}xmsg, $_, WIDTH }
   split m{ (?<= \)) (?= \() }xms,
   $u
   ;
 ;;
 print qq{'$s'};
"
'(x1,y7)(x1,y9)(x2,y3)(x2,y5)(x11,y6)(x11,y8)(x22,y2)(x22,y4)'

[qwerty155]

Sorry, you're right. Sometimes it's hard to find the answer when you're not sure what you're actually looking for (and a newbie).

Thanks for the swift reply.

[Anonymous Monk]

<EffectivnessDetective Rating="mildly amusing">
  <Title IsNotEffective EffectivnessScore="-2">
   <HasStopWord> simple </HasStopWord>
   <HasStopWord> question </HasStopWord>
   <HasStopWord> hopefully </HasStopWord>
   <HasGoWord> sorting </HasGoWord>
   <AutoSuggested>
     <AutoTitle> sorting coordinates first by x then by y </AutoTitle>
     <RelatedNode id="544435"> Sorting large sets of geometric coordinates </Node>
    </AutoSuggested>
  </Title>
  <Question IsEffective HasReceivedAnswer IsFaq EffectivnessScore="2">
    <HasCodeTags />
    <HasCoherentQuestion />
    <DoesNotHaveRealInput />
    <DoesNotHaveRealOutput />
    <DoesNotHaveExpectedOutput />
    <DoesNotHaveRealExpectedOutputDelta />
  </Question>
</EffectivnessDetective>

[wfsp]

Code tags would have been nice. :-)

[jdporter]

XML Sucks.

[sundialsvc4]

Briefly, your sort-comparison function will consider x first, and then consider y only when the values of x are equal.   You also may need to do a little magic (e.g. “<” vs. “lt”) to be certain that the comparison being performed is, in fact, a numeric one.   Test thoroughly.