saving matching pattern with flip-flop operator

[raja_infy]

Hi,

I have a question on flip-flop operator. I have a script something like this

while (<>) {
   if(/START/.../END TIME (.+)/) {
     next if(/START/ | /^\s*$/);     
     print;
   }
}

The flop string 'END TIME (.+)' has a variable time at the end which I would like to extract and print. I see that the script match the 'END TIME (.+)', returns false and returns to the while loop beginning, but the matched sub-pattern (.+) is not stored anywhere ($1, $&, $+ etc). How do I extract this ?

Thanks in advance

-Raja

[bart]

You could use $1, but I expect problems with retained old values if the regex didn't match.

So I prefer to directly, explicitly capture the captured value. Like this:

while (<>) {
    if(/START/ ... (my($time) = /END TIME (.+)/)) {
     unless(defined $time) {
        next if /START/ || /^\s*$/;
        print;
     } else {
        print "End time at $time\n";
     }
   }
}

BTW | is for bitwise or; you (ought to) want either or or ||.

[wfsp]

The second regex clears the capture from the first.

while (<DATA>) {
  if(/START/.../END TIME (.+)/) {
    my $time = $1;
    next if(/START/ | /^\s*$/);     
    print $time, qq{\n};
  }
}
__DATA__
START
END TIME 123
START

END TIME 456

123
456

[planetscape]

See also: Flipin good, or a total flop?

[Anonymous Monk]

but the matched sub-pattern (.+) is not stored anywhere

Yes it is

#!/usr/bin/perl --
use strict;
use warnings;
Main( @ARGV );
exit( 0 );
sub Main {
    for my $outer ( 1 .. 3 ) {
        printf qq[%5s %5s %5s %5s \n], qw' out inn flip $1 ';
        for my $inner (1..10){
            my $flip =   $inner =~ /2/ .. $inner =~ /(5)/ ;
            printf qq[%5s %5s %5s %5s \n], $outer, $inner, $flip, $1 |
+|'';
        }
        print "\n";
    }
}
        
__END__
  out   inn  flip    $1
    1     1
    1     2     1
    1     3     2
    1     4     3
    1     5   4E0     5
    1     6           5
    1     7           5
    1     8           5
    1     9           5
    1    10           5

  out   inn  flip    $1
    2     1
    2     2     1
    2     3     2
    2     4     3
    2     5   4E0     5
    2     6           5
    2     7           5
    2     8           5
    2     9           5
    2    10           5

  out   inn  flip    $1
    3     1
    3     2     1
    3     3     2
    3     4     3
    3     5   4E0     5
    3     6           5
    3     7           5
    3     8           5
    3     9           5
    3    10           5

[choroba]

Do you really want to use binary OR in the next if condition?