You don't want to define MyCollection as a class. Define it as a parameterised role instead. IIRC, there is some MooseX::Declare syntactic sugar for parameterised roles, but I can't remember exactly how it goes, and it's undocumented.
package MyCollection;
use MooseX::Role::Parameterized;
parameter type => (
isa => 'ClassName',
required => 1,
);
parameter attr => (
isa => 'Str',
required => 1,
);
role {
my $p = shift;
my ($type, $attr) = ($p->type, $p->attr);
has $attr => (
is => 'rw',
isa => "HashRef[$type]",
traits => ['Hash'],
defaults => sub { {} }
);
method "summon_$attr" => sub {
my $self = shift;
foreach my $item (values %{ $self->$attr }) {
$item->summon if $item->does('Summonable');
}
};
};
# and we'll use MooseX::Declare syntax for the rest...
role Summonable {
requires 'name';
method summon {
say "Come here, ", $self->name;
}
}
class Child with Summonable {
has name => ( is => 'ro', isa => 'Str' );
}
class Parent {
with MyCollection => { type => 'Child', attr => 'children' };
}
my $me = Parent->new;
$me->children->{isabel} = Child->new(name => 'Isabel');
$me->children->{elliott} = Child->new(name => 'Elliott');
$me->summon_children;
The above is untested, and probably has some syntax errors lurking somewhere, but it should give you an idea of how it can be done.