forcing list-context

[morgon]

Hi,

I need to find the number of entries in a directory, so I do this:

opendir my $dh, $dir or die $!;
my $entries = grep {1} readdir $dh;

What bugs me is the "grep {1}"-thing that I do for the sole purpose of forcing a list-context on the readdir as doing simpy a $entries = scalar (readdir $dh) (i.e. putting paentheses around the call) does not do the trick...

So I wonder now: What is the idiomatic way to force list-context?

Many thanks!

[choroba]

Assign to an emtpy list:

my $entries =()= readdir $dh;

[pvaldes]

... minus 2, unless you want to sum . and ..

[educated_foo]

AKA the "goatse operator" -- google it!

[AnomalousMonk]

goatse ... google it!

NoNoNoNoNoNoNoTenThousandTimesNo!

[LanX]

I most certainly think you meant the rolex operator! ;-)

[BrowserUk]

Unfortunately, even the squeeze operator will still build a long list then discard it, in order to count its members.

More efficient would be:

my $entries = -2;
++$entries while readdir $dh;

[JavaFan]

Well, scalar enforces scalar context, not list context. It's the LHS of the assignment that determines context. Putting the readdir in list context is easy:

    my ($entries) = readdir $dh;

Note that this not solve your problem. Because you phrased it as an XY problem. You want to solve X, you think Y solves X, so you ask how to solve Y. But Y (putting readdir in list context) does not solve X (finding out the number of entries in a directory). At least, not directly. You can assign the result of readdir to a list and put that assignment in scalar context; this will give you the number of entries in the directory. One way of doing this is:

    my $entries = () = readdir $dh;

The parens here indicate an (empty) list.

[morgon]

Well, scalar enforces scalar context, not list context.

I know that.

I did not try to enforce list-context with "scalar" but by putting the expression I wanted to evaluate in list-context in parentheses.

[ikegami]

There are two assignment operator.

• The scalar assignment operator imposes scalar context on both of its operands.
• The list assignment operator imposes list context on both of its operands.

The choice of which assignment operator is used is based on what syntax of its LHS operand. If it "looks like a list", the list assignment operator will be used.

(my $first_entry) = grep ...;
my ($first_entry) = grep ...;
my @entries = grep ...;

Related: Mini-Tutorial: Scalar vs List Assignment Operator.

[Arunbear]

Another way is to unload the readdir call into a temporary array and then call scalar on that e.g.

say scalar(@{[readdir $dh]});

Though this is not as economical (memory wise) as the above solution in Re: forcing list-context

[pvaldes]

I need to find the number of entries in a directory.

my $dir = '/home/itsme/some/dir';
chdir $dir;
my $filenum = 0;
my $dirnum = 0;
my $linknum = 0;
opendir my $dh, $dir or die $!;
foreach(readdir $dh) {
    if (-f){$filenum++}
    elsif (-l){$linknum++}
    elsif (-d){$dirnum++}
    }
    
print "You have $filenum files, $linknum links and $dirnum directories
+ in $dir\n";
closedir $dh;

*(please note that this count is not recursive)

Updated: chdir line added (random results if this line is not activated)

[jwkrahn]

foreach(readdir $dh) {
    if (-f){$filenum++}
    elsif (-l){$linknum++}
    elsif (-d){$dirnum++}
    }

You are not going to get an accurate total because you are counting soft links in both $filenum and $linknum.    That would be better as:

foreach ( readdir $dh ) {
    lstat;
    if    ( -f _ ) { $filenum++ }
    elsif ( -l _ ) { $linknum++ }
    elsif ( -d _ ) { $dirnum++ }
    }