Re: Insert checkbutton into MListbox

[thundergnat]

I'm not familiar with Mlistbox but after a quick perusal of the docs, it look like it is based on a Listbox primitive rather than one of the tix based List widgets. (TList, Hlist, tixGrid, etc.) Listboxs are designed and optimized to work with text items. I'm not sure if it is possible to make them work with other types of items without major aggravation.

For what it is worth, here is an example Checkbuttons in a TList (which IS a tix based List widget)

#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use Tk::TList;

my %tk;

$tk{mw} = MainWindow->new;

$tk{tlist} = $tk{mw}->TList(
  )->pack(
    -expand => 1,
    -fill   => 'both',
  );

my @cbvar = ( 0, 1, 1, 0, 0 );

for ( 0 .. $#cbvar ){
    $tk{"cb$_"} = $tk{tlist}->Frame;

    $tk{"cb$_"}->Checkbutton(
        -variable => \$cbvar[$_]
    )->pack( 
        -side => 'left'
    );

    $tk{"cb$_"}->Label(
        -text => " Checkbox $_ "
    )->pack(
        -side => 'left'
    );
    
    $tk{tlist}->insert( 'end',
        -itemtype => 'window',
        -widget => $tk{"cb$_"},
    );
}

MainLoop;