Re: Using Number Ranges in a Dispatch Table

[afoken]

The map trap. Run this:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %oops=(
    A => 1,
    map { $_ => 2 } ('B','C'),
    map { $_ => 3 } ('D','E'),
    F => 4,
);

print Dumper(\%oops);

Look at the output. Then add ( ) around each map expression:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my %oops=(
    A => 1,
    (map { $_ => 2 } ('B','C')),
    (map { $_ => 3 } ('D','E')),
    F => 4,
);

print Dumper(\%oops);

Alexander

[planetscape]

Bless you!

I thought the technique itself should be sound, and the solution something simple, but I didn't realize it would be this simple!

Thanks!

[Anonymous Monk]

No need to double up on the parentheses

    (map { $_ => 2 } 'B','C'),
    (map { $_ => 3 } 'D','E'),

[ForgotPasswordAgain]

If we're being nitpicky :) no need to create a lexical block for map:

$ perl -Mstrict -MData::Dumper -we'my%h=( (map +($_=>2), "B","C","D"),
+ one=>1 ); print Dumper(\%h)'
$VAR1 = {
          'one' => 1,
          'D' => 2,
          'C' => 2,
          'B' => 2
        };

[oko1]

But isn't this always the case when you're dealing with statements that take lists as arguments?

# Ooops!
print join ",", @foo, "\n";

# Ooops!
print grep /o/, @foo, "Hello world!\n";

# Ooops!
print table{
    map {
        tr(td($_->[0]), td($_->[1])) } @foo,
        ...

My rule of thumb is, if one of these statements is followed by anything besides its argument, then parenthesize that statement's entire argument list.

# De-oopsed.
print join(",", @foo), "\n";
print grep(/o/, @foo), "Hello world!\n";
print table{
    map({
        tr(td($_->[0]), td($_->[1])) } @foo),
        ...