Changing the order of elements in the variable

[Shaveta_Chawla]

$author = "Smith, Kristin A.; Shirley, Mark Harper ; Saff, David ; Ernst, Michael D.; Patrick, Nicholas J. M ; Yu, (Jeffrey) Hu; De La Macorra, F ; Smith, Meghan. ";

this variable has author names , but my target is to change the order of individual author, like "Smith, Kristen A." should change to "Kristen A. Smith".

I have used the following code::

@author = split(';', $author);
$ca = scalar(@author);
for (my $i=0; $i<$ca ; $i++)
{
    ($a, $b) = split(',', $author[$i]);
    $author[$i] = "$b$a";

}
$author = join(',', @author);
print "$author\n";

i find this code really complex. Please suggest a better code using map function.

[moritz]

$author = join '; ',
    map { join ' ', reverse split /, / }
    split /; /, $author;

Or as a regex substitution:

$author =~ s/([^,;]+),([^,;]+)/$2 $1/g;

[bimleshsharma]

That's fantastic.. But one comma (,) is missed- it seems.

$author =~ s/([^,;]+),([^,;]+)/$2, $1/g;

[kcott]

You can check this sort of thing on the commandline: usually advisable if you're going to tell someone they got something wrong.

Shaveta_Chawla wants: "... "Smith, Kristen A." should change to "Kristen A. Smith".".

moritz' solution does this:

$ perl -Mstrict -Mwarnings -E 'my $author = q{Smith, Kristen A.}; $aut
+hor =~ s/([^,;]+),([^,;]+)/$2 $1/g; say $author'
 Kristen A. Smith

Your correction does not do this:

$ perl -Mstrict -Mwarnings -E 'my $author = q{Smith, Kristen A.}; $aut
+hor =~ s/([^,;]+),([^,;]+)/$2, $1/g; say $author'
 Kristen A., Smith

[choroba]

I am not sure it is any "better". Even a smaller improvement (e.g. using for (@author) { ... } instead of the C-style loop can please someone.

#!/usr/bin/perl
use warnings;
use strict;

my $author = 'Smith, Kristin A.; Shirley, Mark Harper ; Saff, David ; 
+Ernst, Michael D.; Patrick, Nicholas J. M ; van der Loede, Greg; Yu, 
+(Jeffrey) Hu; De La Macorra, F ; Smith, Meghan. ';

$author =~ s/.\s*$//;

print((join ', ', map {
    join ' ', reverse split / *, */;
} split / *; */, $author), '.');

[MidLifeXis]

A note on this section of code:

    ($a, $b) = split(',', $author[$i]);

It is often recommended not to use $a and $b, as they are special-cased in some functions within perl (sort, for example). You could get some funky results if you collide with one of these cases. "Better" names might be $lastName and $firstNameAndInitial or $partBeforeComma and $partAfterComma.

You could also trim off the space along with the comma with: split(',\s+', ...), but then you need to also adjust your assignment in the next line.

[uday_sagar]

Your had almost reached, but I see that you have got a slight confusion between comma (,) and semicolon (;)

These are the slight changes to your code:

    
            line 6,      $author\[$i\] = "$b, $a"; 
            line 9,      $author = join(';', @author);

Thats it! :-)