Default variable within loops

[oldwarrior32]

Dear monks. A noob asking for your wisdom again. I did the respectively search in the monastery and the profane Google with no luck.

I have this code:

foreach(@a){
$temp = $_;
$test = grep($temp eq $_,@b);
print "$test\n";
    }

As you can see I needed a '$temp' variable to make the thing work.

Is there a way to evaluate the grep expresion using only default variables, or the '$temp' variables is completely necessary?

Thanks for your help.

By the way, the program just output the amount of elements from array @a that are not in array @b.

[Kenosis]

Here another option using smart matching:

use Modern::Perl;

my @a = 1 .. 10;
my @b = 5 .. 14;

say grep $_ ~~ @b, @a;

Output:

5678910

Hope this helps!

[cheekuperl]

Is this Perl version specific?

[Kenosis]

Smart matching started in Perl 5.10

[aaron_baugher]

elements from array @a that are not in array @b

The more idiomatic way to do this is with a lookup hash. The combination of for/grep is actually two nested loops, meaning that you do a*b comparisons. A hash lookup will be faster for most situations, and clearer to anyone with much Perl experience. To show elements of @a not in @b:

#!/usr/bin/env perl
use Modern::Perl;

my @a = qw/ foo bar baz /;
my @b = qw/ foo bar biz /;

my %b = map { $_ => 1 } @b;

for (@a){
    say unless $b{$_};
}

[muba]

use strict;
use warnings;

my @a = qw(foo bar baz);
my @b = qw(foo bar biz);

foreach my $temp (@a){
    my @matches =  grep {$temp eq $_} @b;
    print "Matches for $temp: ", join(", ", @matches), "\n" if @matche
+s;

}

[frozenwithjoy]

Three things:
• The reason you find that you need to use $temp is that you the $_ associated with the grep is referring to an element of @b, not @a.
• The reason you are getting a count instead of the actual matches is that you are assigning the results to a scalar, not an array.
• One more thing... I believe you are testing for equivalency instead of checking for a pattern match. If you want to perform a typical grep, maybe use something like grep( $temp =~ /$_/, @b )

[stevieb]

I couldn't come up with anything shorter than muba. I tried, but you need at least one temp var (afaict), or else the $_ will confuse iteslf.

my @a = qw( a b c );
my @b = qw( a 3 c );

for my $elem (@a){
    print $elem if grep { $elem eq $_ } @b;
}

[Kenosis]

elements from array @a that are not in array @b

Here's another option for that:

use Modern::Perl;
use List::Compare;

my @a = 1 .. 10;
my @b = 5 .. 14;

my $lc = List::Compare->new(\@a, \@b);

say $lc->get_unique;

Output:

1234

ps Aaron, I always appreciate your postings...

[cheekuperl]

the program just output the amount of elements from array @a that are not in array @b
There's a recipe given in Programming Perl for this.

For default variable within loops- I think its not possible (atleast on Perl v5.8.9). I tried this:

@a=(11,22,33,44,55);
@b=(22,44,66,17);
foreach (@a) # $_ gets one value from @a
{
  @tested=grep {$_ == $::_} @b; # Had $_ been lexical for grep, $::_ w
+ould've been a global
}
print "\n@tested"; #Doesn't work as expected...$_ and $::_ both are sa
+me and get each value from @b

Doesn't look like $_ can be made lexical to grep block.

[zentara]

You might the discussion of default variables in loops at Ovid's Beginners Tutorial... Chapter 5 Control Flow illuminating. It discusses this very point under the section Arrays.

[Anonymous Monk]

Although variables such as $_ are available, they are cryptic, and visually ambiguous when there are nested loops.   Avoid the practice.   Be clear.   Don’t write code that will break merely because you changed it.

[oldwarrior32]

Thanks all!

Just wanted to be sure I was doing the right thing.