How to find what options are used for Getopt::Long

[doubledecker]

Hi Monks

Is there any way that we can find out from my current perl script of which options I've passed for running this script. I'm using Getopt::Long inside my perl script. any hash which will tell me what options i've used to invoke the script as I've bunch of options used

[toolic]

Another way is to store all your opt in a hash instead of individual scalars:

use warnings;
use strict;
use Getopt::Long;
use Data::Dumper;
$Data::Dumper::Sortkeys=1;

my %opt;
GetOptions(\%opt, qw(
    help
    cfg=s
    verbose
    silent
    dir=s
)) or die "Mandatory options not supplied\n";

print Dumper(\%opt);

__END__

script.pl -h -v

$VAR1 = {
          'help' => 1,
          'verbose' => 1
        };

• Getopt::Long

[doubledecker]

Works for me

[Anonymous Monk]

perlvar#@ARGV

[cztmonk]

Maybe you should post some code to make your question more clear...

[doubledecker]

here is my code

#!/usr/bin/perl

use strict;
use Getopt::Long;
$Getopt::Long::autoabbrev = 1;
$Getopt::Long::ignorecase = 0;

my ($opt_help, $opt_cfg, $opt_verbose, $opt_silent, $opt_dir);

GetOptions(
            "help"    => \$opt_help,
            "cfg=s"   => \$opt_cfg,
            "verbose" => \$opt_verbose,
            "silent"  => \$opt_silent,
            "dir=s"   => \$opt_dir,
          ) or die "Mandatory options not supplied\n";

# How to find out which option is passed via Getopt.
# I can rely on the variables for their definedness, but options might
+ increase and
# considerably. Is there any short way that I can find where all the o
+ptions are stored
# say in a hash.

[Anonymous Monk]

#!/usr/bin/perl --
my @argv = @ARGV;
... your code here ...
use Data::Dump;
dd {  before => \@argv, after => \@ARGV };