comment on

bart,
Your code doesn't do the complete patience sorting, it does more or less sort, but you're left with some sorted piles of cards after it finishes — typically 11 piles for a deck of 52 cards, I read. You still need to do the second step: pick the lowest card from every pile, but you don't know what pile that is — except when you just start, then it's the leftmost one. It would be some form of merge sort.

No additional sorting is required to find the longest increasing subsequence. As far as picking the lowest card from every pile - that is easy, it is the top card in each pile.

print "$_->[-1][VAL]\n" for @pile;
[download]

I think you tripped over your wording. I believe you intended to say that at the end of the game, the cards are still not in complete order. While you can get the 1st card for free (the top card on the left most pile), the second card still requires scanning the lowest top card from each pile.

As I said, this is unnessary for finding the longest increasing subsequence which is what this meditation was about. The straight forward approach to finish the sorting would indeed be a merge sort. To make it even more efficient, the piles could be part of a balanced btree. You always select from the left-most pile and then re-insert that pile back into tree based off the card underneath.

The questions to ponder were from the perspective of still finding the longest increasing subsequence.

As far as the binary search. I have 2 versions here to get to the partial sort (sufficient to find the longest increasing subsequence) so benchmarking should be trivial. As far as to complete the sorting - I mentioned one possible way of making it more efficient then a merge sort above but I am not planning on taking it that far. IOW - left as an exercise for the reader. Here is the merge sort though so you have a complete answer to your original question in the CB:

#!/usr/bin/perl
use strict;
use warnings;
use List::Util 'shuffle';

use constant VAL  => 0;
use constant PREV => 1;

my @list = shuffle(1..20);
print "@list\n";
print join " ", Long_Inc_Sub(@list);

sub Long_Inc_Sub {
    my @list = @_;
    my (@pile, @seq);

    # Partial patience sort (w/o bin search) to get LIS

    NUM:
    for my $num (@list) {
        for (0 .. $#pile) {
            if ($num < $pile[$_][-1][VAL]) {
                my $prev = $_ ? $#{$pile[$_ - 1]} : undef;
                push @{$pile[$_]}, [$num, $prev];
                next NUM;
            }            
        }
        my $prev = @pile ? $#{$pile[-1]} : undef;
        push @pile, [[$num, $prev]];
    }

    # Obtain LIS for return

    my ($prev, $len) = ($#{$pile[-1]}, scalar @pile);   
    while ($len--) {
        $seq[$len] = $pile[$len][$prev][VAL];
        $prev = $pile[$len][$prev][PREV];
    }

    # Finish patience sorting via a mergesort
    my @order;

    while (@pile) {
        my ($low, $idx) = (undef, undef);
        for (0 .. $#pile) {
            my $val = $pile[$_][-1][VAL];
            ($low, $idx) = ($val, $_) if ! defined $low || $val < $low
+;
        }
        push @order, $low;
        pop @{$pile[$idx]};
        splice(@pile, $idx, 1) if ! @{$pile[$idx]};        
    }

    # print "$_\n" for @order;
    return @seq;
}
[download]

You can avoid push and splice by presizing @order and testing for definedeness respectively. These optimizations along with the use of the binary search are of course up to you.

Cheers - L~R

In reply to Re^2: Patience Sorting To Find Longest Increasing Subsequence by Limbic~Region
in thread Patience Sorting To Find Longest Increasing Subsequence by Limbic~Region

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


Do you know where your variables are?
	PerlMonks