use strict;
use LWP::Simple;
use HTTP::Daemon;
use HTTP::Status;
use HTTP::Cookies;
use LWP::UserAgent;

open(CSS,"style.css") || die "CSS Error: $!";
my $css = join("",<CSS>);
close(CSS);

my $ua = new LWP::UserAgent;
my $co = HTTP::Cookies->new();
$ua->cookie_jar($co);
my $d=HTTP::Daemon->new(LocalAddr=>'localhost',
                        LocalPort=>'99',
                        Reuse => '1') || die "Cant Spawn: $!";
                        
while(1) 
{
  my $c = $d->accept;
  my $r = $c->get_request();
  my $url = $r->uri->as_string;
  my $content;
    
  if ($url !~ /style.css$/i)
  {
    $url = "http://www.perlmonks.org$url";
    my $req;
    
    if ($r->method eq "GET")
    {
      $req = new HTTP::Request GET => $url;
    }
    else
    {
      $req = new HTTP::Request POST => $url;
      $req->content_type($r->content_type);
      $req->content($r->content);
    }
    
    my $res = $ua->request($req);
    $content = $res->content;
    $content = &dosubs($content);
  }
  else
  {
    $content = $css;
  }
  
  my $response = HTTP::Response->new();
  $response->content($content);
  
  $c->send_response($response);
  $c->close;
}

sub dosubs
{
	$_ = shift;
	s|<body|<link rel=stylesheet type="text/css" href="/style.css" />\n<body|i;
	
	####DEFINE SUBSTITUTIONS HERE####
	
	s/#FFFFFF/#EEEEEE/gi;
	s/border=1//gi;
	s/("checkbox")/$1 class="noborder"/gi;
	s/(INPUT type=radio)/$1 class="noborder"/gi;
	s/("radio")/$1 class="noborder"/gi;
	s/<font size=2/<font style="text"/gi;
	s/www\.perlmonks\.org/localhost:99/gi;
	
	#################################
	$_;
}