#!/usr/bin/perl
use warnings;
use strict;
use Data::BitStream::XS;
use Text::CSV;
use autodie;
my $use_arice = 1;

my $csv = Text::CSV->new({ sep_char => ',' });

{
  my $file = 'accel.csv';
  open(my $data, '<', $file);
  my @prev = (0, 0, 0, 0);
  my @rice = (4, 4, 4, 4);
  my @egol = (8, 6, 6, 5);

  my $stream = Data::BitStream::XS->new( file => 'accel.gamma', mode => 'w' );

  while (my $line = <$data>) {
    next if $line =~ /^;/;
    $line =~ s/[\r\n]//g;
    die "Bad CSV: $line" unless $csv->parse($line);
    my @fields = $csv->fields();
    $fields[0] = int($fields[0] * 10000 + 0.5);  # Drop last two digits

    foreach my $n (0..3) {
      my $p = $prev[$n];
      my $v = $fields[$n];
      my $delta = $v - $p;
      my $udelta = ($n == 0) ? $delta
                             : ($delta >= 0)  ?  2*$delta  :  -2*$delta-1;
      $use_arice ? $stream->put_arice($rice[$n], $udelta)
                 : $stream->put_expgolomb($egol[$n], $udelta);
    }
    @prev = @fields;
  }
  close($data);
  $stream->write_close;
}

# Verify we can read the stream back and write a CSV file
{
  my @prev = (0, 0, 0, 0);
  my @rice = (4, 4, 4, 4);
  my @egol = (8, 6, 6, 5);

  my $stream = Data::BitStream::XS->new( file => 'accel.gamma', mode => 'ro' );
  my $file = 'new.csv';
  open(my $data, '>', $file);

  while (my $v = $use_arice ? $stream->get_arice($rice[0])
                            : $stream->get_expgolomb($egol[0])  ) {
    my $time = $prev[0] + $v;
    $prev[0] = $time;
    
    printf $data "%.4f", ($time/10000);

    foreach my $n (1..3) {
      my $udelta = $use_arice ? $stream->get_arice($rice[$n])
                              : $stream->get_expgolomb($egol[$n]);
      my $delta = (($udelta & 1) == 0) ? $udelta >> 1 : -(($udelta+1) >> 1);
      my $v = $prev[$n] + $delta;
      print $data ',', $v;
      $prev[$n] = $v;
    }
    print $data "\n";
  }
  close($data);
}