http://www.perlmonks.org?node_id=274443


in reply to Is there a Limit on Matching .*

I am actually a bit shocked that no-one mentioned using a negated character class to grab what you need. The idea is to grab everything that is not the character '<': 
my ($title) = $chunk =~ /<title>([^<]+)/;
my @h1      = $chunk =~ /<h1>([^<]+)/g;

[download]
However, this is still not perfect. I personally think that nothing is too simple for a parser module, especially if that parser module is HTML::TokeParser::Simple: 
use strict;
use warnings;

use Data::Dumper;
use HTML::TokeParser::Simple;

my $d = do {local $/;<DATA>};
my $p = HTML::TokeParser::Simple->new(\$d);
my %hash;

while ( my $token = $p->get_token ) {
   $hash{title} = $p->get_token->return_text
      if $token->is_start_tag('title');
   push @{$hash{h1}}, $p->get_token->return_text
      if $token->is_start_tag('h1');
}

print Dumper \%hash;

__DATA__
<html>
<head>
<title>foo</title>
</head>
<body>
<h1>one</h1>
<h1>two</h1>
<h1>three</h1>
</body>
</html>

[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

In Section Seekers of Perl Wisdom