http://www.perlmonks.org?node_id=11123877


in reply to Find combination of numbers whose sum equals X

#!/usr/bin/perl
use warnings;
use strict;

sub _summands {
    my ($target, @numbers) = @_;
    return [[]] if 0 == $target;

    my @results;
    for my $index (0 .. $#numbers) {
        my $number = $numbers[$index];
        my @remaining = @numbers[ grep $_ != $index, 0 .. $#numbers ];
        next if $target - $number < 0;

        my $result = _summands($target - $number, @remaining);
        push @results,
            map [$number, @$_],
            grep ! @$_ || $number <= $_->[0],
            @$result;
    }
    return \@results
}

sub summands {
    my $results = _summands(@_);
    my %unique;
    for my $result (@$results) {
        undef $unique{"@$result"};
    }
    return [ map [split ' '], keys %unique ]
}

use Test::More tests => 2;
use Test::Deep;

cmp_deeply summands(100, 1, 99, 2, 40, 50, 60, 90, 3, 5, 95, 100),
    bag([100], [1, 99], [2, 3, 95], [5, 95], [2, 3, 5, 90], [2, 3, 5, 
+40, 50], [40, 60]);

cmp_deeply summands(100, 5, 5, 5, 5, 10, 15, 80, 99),
    bag([5, 15, 80], [5, 5, 5, 5, 80], [5, 5, 10, 80]);

[download]

Update: Sorry, I'm kind of busy, so I don't have much time to explain it. It's a classical example of Dynamic Programming - the only complication is the numbers can be repeated, which I solved using the $unique hash. It's probably possible to build the solutions in a unique way right away in the recursive function, so there won't be any postprocessing needed.

Update 2: For a speed-up, add 

use Memoize;
memoize('_summands');

[download]
and, as found by haukex in Fastest way to "pick without replacement", replace 
        my $number = $numbers[$index];
        my @remaining = @numbers[ grep $_ != $index, 0 .. $#numbers ];

[download]
by 
        my @remaining = @numbers;
        my ($number) = splice @remaining, $index, 1;

[download]

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

Replies are listed 'Best First'.
Re^2: Find combination of numbers whose sum equals X
by harangzsolt33 (Chaplain) on Nov 20, 2020 at 15:27 UTC
    Wow, thank you very much for all your answers! These replies have been very enlightening! :-)
[reply]

In Section Seekers of Perl Wisdom