Regx: match without regarding space and case

[atemon]

There are 2 strigs, say

$x="My name is VC";
$y="myname";

I want to search for $y in $x regardless of the spaces and case and retrieve the matched string in $x. In $x, the extra character comes can be space (only) and it can come any number of times like "My Na me"

We can match by making a temp string and removing space and match. Then I cant get the matching string :(

Thanks in advance.

--VC

---

There are three sides to any argument.....
your side, my side and the right side.

[Sidhekin]

This works for me:

my $x="My name is VC";
my $y="myname";

my $r = do { local $" = ' *'; my @r = split //, $y; qr/@r/i };

if ($x =~ /($r)/) {
  printf "Matched from %d to %d: '%s'\n", $-[0], $+[0], $1;
}

Prints:

Matched from 0 to 7: 'My name'

[GrandFather]

Use the translate operator (see tr/SEARCHLIST/REPLACEMENTLIST/cds) to delete the spaces, then use a case insensitive match. The code below captures the matched string to retain the original case, but doesn't attempt to figure out the "spacey" version of the match:

use strict;
use warnings;

my $x="My name is VC";
my $y="myname";

$x =~ tr/ //d;
print "Matched: >$1<\n" if $x =~ /(\Q$y\E)/i;

Prints:

Matched: >Myname<

[Skeeve]

but doesn't attempt to figure out the "spacey" version of the match:

But getting the spacey version was what the OP was asking for, wasn't it?

[Skeeve]

A variation of Sidhekin's solution:

#!/usr/bin/perl
my $x="My name is VC";
my $y="myname";

my $r;
($r=$y)=~ s/(\S)(?!$)/$1 */g;
$r= qr/($r)/i;

if ($x =~ $r) {
  printf "Matched from %d to %d: '%s'\n", $-[0], $+[0], $1;
}

[narainhere]

Adding up to it, is there a way to differentiate the space characters \s and \t (That means a single space like ' ' and a tab like (' ') this.

[Roy Johnson]

\s is not a space, but is any whitespace, including tab and newline. You differentiate " " from "\t" just like this.