size of an array ref

[fionbarr]

How do I know the size of a reference to an array....

  DB<22> x @a
0  ARRAY(0x8d1814)
   0  123
   1  456
   2  789

if I say scalar @a....I get '1'...I want to get '3'. Thanks

[roboticus]

fionbarr:

You need to use scalar(@{$a[0]}) to get 3. Your array contains only one element, the array reference. So if you want 3, you need to ask the referenced array for its size, not the container. Perhaps this example will help:

$ cat t.pl
#/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my @a = (1, 2, 3);

print "Size of a: ", scalar(@a), "\n";
print Dumper(\@a),"\n";

my @b = [0, 1, 2];
print "Size of b: ", scalar(@b), "\n";
print Dumper(\@b),"\n";

print "Size of b[0]: ", scalar(@{$b[0]}), "\n";
print Dumper($b[0]),"\n";

which gives us:

$ perl t.pl
Size of a: 3
$VAR1 = [
          1,
          2,
          3
        ];

Size of b: 1
$VAR1 = [
          [
            0,
            1,
            2
          ]
        ];

Size of b[0]: 3
$VAR1 = [
          0,
          1,
          2
        ];

...roboticus

When your only tool is a hammer, all problems look like your thumb.

[fionbarr]

that's it! Thanks guys! # array: $ perl -wE 'my @a = qw/a b c/; say scalar @a' 3 # array ref: $ perl -wE 'my $a = qw/a b c/; say scalar @$a'perfect!

[moritz]

# array:
$ perl -wE 'my @a = qw/a b c/; say scalar @a'
3
# array ref:
$ perl -wE 'my $a = [qw/a b c/]; say scalar @$a'
3

See also: perlreftut, References Quick Reference

[fionbarr]

that makes sense...I might have a reference to a reference to an array...I've tried a lot of permutations and not gotten '3'...is it possible to get the size of a ref to a ref?

[JavaFan]

      @array;
     @$arrayref;
    @$$arrayrefref;
   @$$$arrayrefrefref;
  @$$$$arrayrefrefrefref;
 @$$$$$arrayrefrefrefrefref;
@$$$$$$arrayrefrefrefrefrefref;
... etc ...

[brx]

$a= [1..10];$b=\$a;$c=\$b; $d=\$c;$e=\$d; 

$e=$$e while (ref($e) eq "REF");
print scalar @$e;

[swampyankee]

A question I can still answer!

The size of a reference to an array is a scalar. If you're looking for the size of the array to which the references is pointing, you may try this:

print scalar(@{a});

The curly braces are the dereference operator. Now, if I misunderstood, and you want to know something like the total size of a array of references to arrays, my answer is likely useless.

[jethro]

Sorry to disappoint you but the curly braces do not dereference, @{a} is equivalent to @a. The curly braces only allow more complicated constructs with unambiguous precedence, for example ${$a[3]}[4] versus ${$a}[3][4]. If you want dereference, @{$a} or simply @$a is the right choice.

Update: Thanks to choroba and SuicideJunkie for spotting a $ where a @ should have been

[swampyankee]

Insert random cursing here. I should have kept my virtual mouth shut.

[Marshall]

#!/usr/bin/perl -w
use strict;

my $aref = [5,6,7,8];
print @$aref,"\n";         #5678
print "@$aref","\n";       #5 6 7 8
print scalar @$aref,"\n";  #4
print ''.@$aref,"\n";      #4   

# using string concatenation in the last example
# puts @$aref in a scalar context

my $ref = [ [qw(a b c)], [qw(x y zzy)] ];
print ''.map{@$_}@$ref;   #6

# $ref is a ref to an array of references
# @$ref makes a list of those references
# the map expands out each array ref into all of its elements
# putting this into a scalar context reports the total number

print @{$ref->[1]},"\n";  #xyzzy

#basically, you need extra {} when a subscript is involved.

[Anonymous Monk]

# Get the size of a reference to an array: my $array_ref = 'this','that','the other'; my $item_count = @{$array_ref};

[TomDLux]

@a is an array. The first element of @a is $a[0], which stores a reference to an array of three elements. You can extract the inner array using @{ $a[0] }. Unlike the other suggestions, this works for the (fictional) array stored in $a[1] or other positions, and it can be extended for the third-level, fourth-level, etc.