Special literals taken literally

[xdg]

Sometimes, mistakes stare you in the face and you still miss them. This brief meditation is on the topic of special literals, one of which recently caused a frustrating bug for me. Realizing what had happened was a bracing reminder about when to use the cruciform operator.

For beginning to intermediate monks, ponder the following code snippet:

# In the file 'literal.pl'
package Illumination;
use strict;
use warnings;
use Data::Dumper;

my %hash;
$hash{__PACKAGE__}{__FILE__}{__LINE__} = "Mu Mu";

print Dumper \%hash;

What will it produce? Check your answer.

[bobf]

Interesting. Apparently, I would have made the same mistake you did. :-)

From perldata (emphasis mine):

The special literals __FILE__, __LINE__, and __PACKAGE__ represent the current filename, line number, and package name at that point in your program. They may be used only as separate tokens; they will not be interpolated into strings. If there is no current package (due to an empty package; directive), __PACKAGE__ is the undefined value.

The original code gives:

$VAR1 = {
          '__PACKAGE__' => {
                             '__FILE__' => {
                                             '__LINE__' => 'Mu Mu'
                                           }
                           }
        };

But the "cruciform operator" can be used to interpolate tokens:

$hash{+__PACKAGE__}{__FILE__}{__LINE__} = "Mu Mu";

$VAR1 = {
          'Illumination' => {
                              '__FILE__' => {
                                              '__LINE__' => 'Mu Mu'
                                            }
                            }
        };

Double-cruciform (++) for the reminder.

[TimToady]

Interestingly, this is fixed two different ways in Perl 6. Instead of special tokens, we have compiler variables like $?PACKAGE and $?FILE. And even if they were still bare identifiers, it would still work, because curlies no longer autoquote. We now use a different notation (angle brackets) for constant string subscripts.

Sorry, I usually try to resist saying "fixed in six", because you'd get tired of it if we said it as often as it's true...

[larryl]

Good point - I was recently similarly burned by something like this:

use constant FOO => 'my hash key';

my %hash = ('my hash key' => 42);

print "Wahoo!\n" if exists $hash{FOO};


This will work as expected:

print "Wahoo!\n" if exists $hash{+FOO};


Larry

[diotalevi]

Well, err, yeah. Shouldn't this have been obvious to you? Fat comma has the same effect. That hash subscripts are treated as strings is nothing new. You've known you can type $foo{BAR} without having to quote "BAR". This is just the same rule. No special magic at all. In fact, that's thing. There's less magic here.

[xdg]

Well, err, yeah. Shouldn't this have been obvious to you?

Yes, it should have. I kicked myself when I realized what I did. This meditation is a reminder, not a discovery.