Inheritance in the same file

Monks,

I have a small inheritance hierarchy in the same file, but how come B can't seen to see A?

Thanks!

I keep getting:

Can't locate object method "new" via package "B" at ./example line 7.

#!/usr/bin/perl
use strict;
use warnings;
require B;


my $a = B->new();



package A;

use strict;
use warnings;

sub new {

   my ($class, %args) = @_; 
   my $self = bless { }, ref($class) || $class;
   return $self;
}


1;



package B;

use strict;
use warnings;
require A;

@B::ISA = qw(A); 

sub _init {
    my ($self, %args) = @_; 
    $self->{_title}    = $args{title}    || undef;
}


1;

[Corion]

B is an already existing package.

require will try to load a file from disk and fail if that file does not exist.

The combination means that some package "B" gets loaded from disk, so your require B never fails.

Your real problem is one of initializsation. @B::ISA gets initialized after your main program has run, so the inheritance chain is never set up.

I recommend reordering your source file to have the main program at the bottom, or better, move the packages out into separate files.

[stephen]

Alternatively, you can wrap the class code in a BEGIN block. That will ensure that your classes are initialized before the main code gets run. You don't need "require" or '1;' when the code is in the same file. Also, 'use strict' is lexically scoped, so you really only need to say it at the top.

#!/usr/bin/perl
use strict;
use warnings;

my $a = B->new();

BEGIN {

    package A;

    sub new {
        my ( $class, %args ) = @_;
        my $self = bless {}, ref($class) || $class;
        return $self;
    }

    package B;

    @B::ISA = qw(A);

    sub _init {
        my ( $self, %args ) = @_;
        $self->{_title} = $args{title} || undef;
    }

}

[yoda54]

Thank you!

[yoda54]

Thanks much!!!