in reply to using Path::Tiny and reformating result

I'm not sure why I'm being warned about wide characters. If I use utf8; and $path1->lines_utf8;, am I not projecting my intent?

Not fully: The utf8 pragma tells Perl that your source file is encoded in UTF-8 (nothing else), and ->lines_utf8 reads the file as a UTF-8 encoded file. The thing missing here is the output: your STDOUT is not set up to output Unicode. Try adding the open pragma: use open qw/:std :utf8/;

As for your formatting questions, I'm not entirely sure I understand - is your output fixed-width, like in a terminal or <pre> tags, or is it HTML?

Replies are listed 'Best First'.
Re^2: using Path::Tiny and reformating result
by Aldebaran (Chaplain) on Jun 26, 2018 at 22:29 UTC

    Thx haukex, that got rid of the warning. I'm not sure that I understand it completely, but I do understand the absence of a warning. I do have suitable output to frame the problem. It's 39 lines of text all told, so if seeing that much data is going to make the reader grumpy, then don't open the readmore tags. I'm hoping to get the pre tags right on this. (Order seems to matter on these tags.)

    New script:

    #!/usr/bin/perl -w
    use strict;
    use 5.010;
    use Path::Tiny;
    use utf8;
    use open qw/:std :utf8/;
     
    # creating Path::Tiny objects
     
    my $dir = path("/home/bob");
    my $name = "1.promises.txt";
    my $new_name = path($dir,"1.revised.txt");
     
    my $path1 = path($dir, $name); # list
    say $path1; 
    #say "lines are @lines";
    my @lines = $path1->lines_utf8;
    
    foreach my $i (0 .. $#lines) 
    {
     say "i is $i";
     say "$lines$i";
     $lines$i =~ s/God/an arbitrary higher power/;
     $lines$i=~ s/Бог/большая сила/;
    }
    
    $new_name->spew_utf8( @lines );
    
    __END__ 
    
    

    A couple problems solved, but I'm still fishing for how I format this into homogenous-looking paragraphs.

    Update: attempting again to use pre tags successfully; using them in conjunction with code tags seems not to display wide characters properly

      attempting again to use pre tags successfully; using them in conjunction with code tags seems not to display wide characters properly

      Yes, the issue with <code> vs. <pre> tags and Unicode characters only working in the latter is a known issue on PerlMonks.

      I'm still fishing for how I format this into homogenous-looking paragraphs.

      Have a look at the core module Text::Wrap. Here's one way, I'm using the "paragraph mode" supported by $/ to read the file:

      use warnings; use strict; use open qw/:std :utf8/; use Text::Wrap 'wrap'; open my $fh, '<:raw:encoding(UTF-8)', '1.promises.txt' or die $!; local $/ = ''; local $Text::Wrap::columns = 71; while (<$fh>) { s/^\s+|\s+$//mg; if (/\A\w+\z/) { print ' ' x int( (71-length)/2 ), $_, "\n"; next; } s/\n|\s{2,}/ /g; print wrap(' 'x5, '', $_), "\n"; } close $fh;

      Output:

                                     Oбещания
           Если эта фаза нашего развития болезненна для нас, мы будем
      удивлены, когда половина пути окажется позади. Мы познáем новую
      свободу и новое счастье. Мы не будем сожалеть о нашем прошлом и вместе
      с тем не захотим полностью забывать о нем. Мы узнаем, что такое
      чистота, ясность, покой. Как бы низко мы ни пали в прошлом, мы поймем,
      что наш опыт может быть полезен другим. Исчезнут ощущения ненужности и
      жалости к себе. Мы потеряем интерес к вещам, которые подогревают наше
      самолюбие, и в нас усилится интерес к другим людям. Мы освободимся от
      эгоизма. Изменится наше мировоззрение, исчезнут страх перед людьми и
      неуверенность в экономическом благополучии. Мы интуитивно будем знать,
      как вести себя в ситуациях, которые раньше нас озадачивали. Мы поймем,
      что Бог делает для нас то, что мы не смогли сами сделать для себя.
           Не слишком ли это звучит многообещающе? Нет. Все это произошло со
      многими из нас, с одними раньше, с другими позже. Все это становится
      явью, если приложить усилия.
                                     Promises
           If we are painstaking about this phase of our development, we
      will be amazed before half through! We are going to know a new freedom
      and happiness. We will not regret the past nor wish to shut the door
      on it. We will comprehend the word serenity and know peace. No matter
      how far down the scale we have gone, we will see how our experience
      can benefit others. That feeling of use- lessness and self-pity will
      disappear. We will lose interest in selfish things and gain interest
      in our fellows. Self-seeking will slip away. Our whole attitude and
      outlook upon life will change. Fear of people and of economic
      insecurity will leave us. We will intuitively know how to handle
      situations which used to baffle us. We will suddenly realize that God
      is doing for us what we could not do for ourselves.
           Are these extravagant promises? We think not. They are being
      fulfilled among us—sometimes quickly, sometimes slowly. They will
      always materialize if we work for them.
      

        Thx, haukex, I was gonna spend a month on that, and I only had a few days before it needs to be done. I was almost through the logic of centering, but yours looks so much cleaner. This is essentially your same program but using Path::Class to specify input and output files and adding a couple customizations for this particular text:

        #!/usr/bin/perl -w
        use strict;
        use 5.010;
        use Path::Tiny;
        use utf8;
        use open qw/:std :utf8/;
        use Text::Wrap 'wrap';
        
        my $dir      = path("/home/bob");
        my $name     = "1.promises.txt";
        my $new_name = path( $dir, "7.revised.txt" );
        my $path1    = path( $dir, $name );
        say $path1;
        say "new name is $new_name";
        open my $gh, '>:raw:encoding(UTF-8)', "$new_name" or die $!;
        open my $fh, '<:raw:encoding(UTF-8)', "$path1"    or die $!;
        local $/                   = '';
        local $Text::Wrap::columns = 71;
        
        while (<$fh>) {
           say "default is $_";
           s/God/a higher power/;
           s/Бог/Высшая Сила/;
           s/^\s+|\s+$//mg;
           if (/\A\w+\z/) {
              print $gh "\n";
              print $gh ' ' x int( ( 71 - length ) / 2 ), $_, "\n";
              print $gh "\n";
              next;
           }
           s/\n|\s{2,}|\t/ /g; 
           print $gh wrap( ' ' x 5, '', $_ ), "\n";
        }
        close $fh;
        close $gh;
        system("gedit $new_name &");
        system("cat $new_name &");
        __END__ 

        I'm still not completely clear what local $/ = ''; does, even with the say statements for $_. It's exactly what I need, but perlvar does not discuss what it means to set it like this, which seems, as you say, to be paragraph mode. (?)