Re: How to de-reference a coderef? (B tricks)

Unlike e.g. array refs, every code ref has a backreference to its glob (so that when you call it, caller can know the sub name). This is fairly easily accessible with the B module (which provides introspection facilities for perl thingies):

use B;
sub coderef2name {
   eval {
      my $obj = B::svref_2object( shift() );
      $obj->GV->STASH->NAME . "::" . $obj->GV->NAME;
   } || undef;
}

Returns something like pkgname::__ANON__ for anonymous subs, or undef if something goes wrong (like being passed an array ref instead of a code ref).

Updated to use GV->STASH->NAME, not STASH->NAME. Thanks, betterworld

[Anonymous Monk]

How do you do this in XS? Given a CV how do you get the name for the corresponding named sub?

[ikegami]

use strict;
use warnings;
use feature qw( say );

use Inline C => <<'__EOI__';

SV* coderef2name(CV* cv) {
   const GV *   const gv        = CvGV(cv);
   const HV *   const stash     = GvSTASH(gv);
   const char * const pkg_name  = HvNAME(stash);
   const char * const func_name = GvNAME(gv);
   SV *         const fqn       = newSVpvn("", 0);

   sv_catpv(fqn, pkg_name);
   sv_catpv(fqn, "::");
   sv_catpv(fqn, func_name);

   return fqn;  // Mortalised by Inline
}

__EOI__

sub f {}

say coderef2name(\&f);

[Anonymous Monk]

You call coderef2name from XS, that is how you do it