#!/usr/bin/perl -T
use warnings;
use strict;
use feature 'say';
use Scalar::Util qw/tainted/;
use DBI;
use DBI::Const::GetInfoType;

my $dbh = DBI->connect(
	"DBI:mysql:database=testing;host=127.0.0.1", $ENV{USER},
	'barfoo', { RaiseError=>1, AutoCommit=>1, TaintIn=>0 });

say "Perl: $]";
say "Database: ",
	$dbh->get_info( $GetInfoType{SQL_DBMS_NAME} ), " ",
	$dbh->get_info( $GetInfoType{SQL_DBMS_VER} );
say "Driver: ", $dbh->{Driver}->{Name};
say "DBI Ver: ", $DBI::VERSION;
say "DBD::mysql Ver: ", $DBD::mysql::VERSION;

$dbh->do('DROP TABLE IF EXISTS Person');
$dbh->do(<<'ENDSQL');
CREATE TABLE Person (
	idPerson VARCHAR(256),
	email VARCHAR(256),
	altEmail VARCHAR(256)
);
ENDSQL
$dbh->do('INSERT INTO Person (idPerson, email, altEmail) VALUES ("hello","foo@bar.com","foo@bar.com");');

die "run me with an empty string as the first argument"
	unless @ARGV && !length $ARGV[0];
my %data = ( email => 'foo@bar.com'.shift(@ARGV) );
die unless tainted($data{'email'});

my $query = $dbh->prepare("SELECT idPerson FROM Person WHERE email = ? OR altEmail = ?");
$query->execute($data{'email'}, $data{'email'});
my ($crid) = $query->fetchrow_array;
say "CRID: $crid";

my ($test) = $dbh->selectrow_array("SELECT idPerson FROM Person WHERE email = ? OR altEmail = ?", undef, $data{'email'}, $data{'email'});
say "TEST: $test";

__END__

Perl: 5.032001
Database: MySQL 5.7.33
Driver: mysql
DBI Ver: 1.643
DBD::mysql Ver: 4.050
CRID: hello
TEST: hello