Re^3: The error says the value is uninitialized, but it works anyway

[AnomalousMonk]

Why is it basically impossible to easily force user input to be a number if it's not a whole number?

mizducky:   Further to the posts of shmem here and afoken here:   It's not (basically impossible, that is). Perl tries hard to obey the Do What I Mean (DWIM) principle. Perl has not, unfortunately, been blessed with powers of telepathy or clairvoyance, but it does what it can within reason. In particular, Perl will try to seamlessly convert back and forth between numbers and strings. Here are some concrete examples. All the examples in this post have warnings and strictures fully enabled.

If you try to add strings that look like integers, floats, etc., the results should be pretty much as you expect (or I should say, as Perl expects you expect):

c:\@Work\Perl\monks>perl -wMstrict -MData::Dumper -le
"my $x = '1.23' + qq{0.34 \t\n\r} + '5.6e3' + '100';
 print Dumper $x;
 ;;
 $x = $x + 98.6;
 print Dumper $x;
 ;;
 my $y = 0 + $x;
 print Dumper $y;
"
$VAR1 = '5701.57';

$VAR1 = '5800.17';

$VAR1 = '5800.17';

Note that one of these strings, qq{0.34 \t\n\r}, has a bunch of whitespace padding at the end and still adds correctly. (I use the generic  qq{...} double-quote operator only because Windows command line turns up its nose at common  "..." double-quotes.) In the Dumper output in this example, the single-quotes around the nummbers (e.g., $VAR1 = '5601.57') indicate that Perl still sees these scalars as strings even after an arithmetic operation with a literal number (update: but see haukex's reply), but what care you as long as the numeric | arithmetic results are correct? (Actually, I can't say offhand just how I would force a scalar into strict "numeric" mode. Shall we say this is left as an exercise for the reader?)

You mention difficulty with a numeric string taken from STDIN. Because it's a newline-terminated string, it should behave just like the highly whitespace-padded string in the foregoing example. (Normally, a program would use chomp to get rid of newline termination on input from STDIN or a file handle, but in this example it's not necessary.)

c:\@Work\Perl\monks>perl -wMstrict -MData::Dumper -le
"my $x = <STDIN>;
 print Dumper $x;
 ;;
 my $y = 56.7 + $x;
 print Dumper $y;
"
2.34
$VAR1 = '2.34
';

$VAR1 = '59.04';

Question: why does the Dumper output
$VAR1 = '2.34
';
above look a bit odd? You don't give an example of the code involving STDIN that gave you difficulty; this is always helpful — see Short, Self-Contained, Correct Example.