note
ELISHEVA
<blockquote><i>Attributes are not for the faint of heart</i></blockquote>
<p>Ain't that the truth! Thank you so much for the suggestion, but it didn't work within <code>MODIFY_CODE_ATTRIBUTES</code>. Sigh... Your "another major catch" seems to be right on. Your proposal exhibits the same behavior as <code>Devel::Peek::Dump</code> - works great after compilation (even in a BEGIN block) but not in <code>MODIFY_CODE_ATTRIBUTES</code>. The association between symbol and name does not appear to be set up until after the <code>MODIFY_CODE_ATTRIBUTES</code> function completes. This small script...</p>
<readmore><code>
use strict;
use warnings;
use Devel::Peek();
BEGIN {
#Many thanks to Thilosophy
#see http://www.perlmonks.org/?node_id=743987 for original source
#on which this is based
sub getOriginalCodeRefName {
my ($pkg, $ref) = @_;
no strict 'refs';
while (my ($key,$val) = each(%{*{"$pkg\::"}})) {
local(*ENTRY) = $val;
if (defined $val && defined *ENTRY{CODE}) {
next unless *ENTRY{CODE} eq $ref;
# rewind "each"
my $a = scalar keys %{*{"$pkg\::"}};
return $key;
}
}
warn "Warning: could not find name for $ref";
return undef;
}
sub MODIFY_CODE_ATTRIBUTES {
my $sPackage = shift @_;
my $crSub = shift @_;
print STDERR "Dumping $crSub in MODIFY_CODE_ATTRIBUTES:\n";
#Devel::Peek::Dump($crSub);
my $sName = getOriginalCodeRefName($sPackage, $crSub);
$sName = 'undef' unless defined($sName);
print STDERR "Name via Thilosophy method: <$sName>\n";
return ();
}
}
BEGIN {
sub bar : Lion {
print "Oh my!\n";
}
print STDERR "\nDumping " . \&bar . " in BEGIN block after compilation.\n";
#Devel::Peek::Dump(\&bar);
my $sName = getOriginalCodeRefName(__PACKAGE__, \&bar);
$sName = 'undef' unless defined($sName);
print STDERR "Name via Thilosophy method: <$sName>\n";
}
</code></readmore>
<p>outputs...</p>
<code>
Dumping CODE(0x81a8e60) in MODIFY_CODE_ATTRIBUTES:
Warning: could not find name for CODE(0x81a8e60) at Monks/Snippet.pm line 23.
Name via Thilosophy method: <undef>
Dumping CODE(0x81a8e60) in BEGIN block after compilation.
Name via Thilosophy method: <bar>
</code>
<p>I am more than a little surprised that it is so difficult to use <code>MODIFY_CODE_ATTRIBUTES</code> to redefine functions. When I scanned the web last night in response to your query on attribute handling it seemed that one of the major use case for attributes is decorating functions. It seems a little strange to add a feature that can't be used for one of its major use cases.</p>
<p>Best, beth</p>
<p><b>Update</b>: fixed some typos, added comment about blocks, some clarifications.</p>
<p><b>Further update:</b> Just reread the Perl documentation for [perldoc://attributes] and I think I finally understand what the last sentence of this quote might mean. Do you suppose "cloned copies ... used as closures" means decorated functions?... and the reason for this non-implementation being that the coderef is only partially set up? (i.e. not part yet of the symbol table)</p>
<blockquote><i>WARNING: the mechanisms described here are still experimental. Do not rely on the current implementation. In particular, there is no provision for applying package attributes to 'cloned' copies of subroutines used as closures.</i></blockquote>
<p>It does appear that the only way to get decorated functions is to set up CHECK handlers or do ugly things like store a hash keyed by code ref and then match up the names and the coderefs later on, a la [mod://Class::Declare].</p>
743987
744042