Re: How to pass parameter to a subroutine?

[tybalt89]

This $i does not participate in closures

for (my $i = 0; $i <= 15, $i++)

whereas this $i does

for my $i ( 0..15 )

so try (slightly tweaked)

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11113672
use warnings;
use Tk;

my %frames;

my $mw = MainWindow->new( -bg=> '#606060', -borderwidth=> 0);
my $size = 40;
my $y = 0;
my $x = 0;
my $h = 3*$size;
for my $j ( 0 .. 15 ) {
    my $x = 0;
    my $w = 3*$size;
    for my $i ( 0 .. 15 ) {
        $frames{"$i,$j"} = $mw->Button( -text => ' ', -bg => "#60C8BC"
+, -fg => "#000000", -borderwidth => 1, -anchor => 'w',  );
        $frames{"$i,$j"}->bind('<Button-1>' => sub { &ToggleBox("$i,$j
+"); } );
        $frames{"$i,$j"}->place( -y=>$y, -x=>$x, -width=>$w, -height=>
+$h );
        $x = $x + $w;
        $w = $size;
        $x = $x+2 if ($i % 5 == 0);
    }
    $y = $y + $h;
    $h = $size;
    $y = $y+2 if ($j % 5 == 0);
}

MainLoop;

sub ToggleBox {
    my $this = shift;
    print "$this\n";
}

Are you sure you don't want to use the grid geometry manager ?

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11113672
use warnings;
use Tk;

my %frames;

my $mw = MainWindow->new( -bg=> '#606060', -borderwidth=> 0);
for my $j ( 0 .. 15 )
  {
  for my $i ( 0 .. 15 )
    {
    $frames{"$i,$j"} = $mw->Button(
      -text => ' ',
      -bg => "#60C8BC",
      -fg => "#000000",
      -borderwidth => 1,
      -anchor => 'w', 
      -command => sub { ToggleBox("$i,$j"); },
      )->grid( -row => $j, -column => $i);
    }
  }

MainLoop;

sub ToggleBox 
  {
  my $this = shift;
  print "$this\n";
  }