matching lines in a long string

[Cristoforo]

Hello monks!

Been working on this problem and can't find my error. I'm trying to use the m modifier to read a large text in line by line. I want to use the inline form, (?m) rather than following the regex slash with m.

#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';

my $s = <<'EOF';
int t; //variable t
t->a=0;  //t->a does;; something
printf("\nEnter the Employee ID : ");
scanf("%d", ptrx->eid);  //employee id ptrx->eid
printf("\nEnter the Employee Name : ");
scanf("%s", ptr->name);
return 0;
EOF

for my $line (split/(?m)\n(?=$)/, $s) {
    say '<' . $line . '>';    
}

I wonder if anyone can see why it isn't working. The output is:

C:\Old_Data\perlp>perl test3.pl
<int t; //variable t
t->a=0;  //t->a does;; something
printf("\nEnter the Employee ID : ");
scanf("%d", ptrx->eid);  //employee id ptrx->eid
printf("\nEnter the Employee Name : ");
scanf("%s", ptr->name);
return 0;>

It isn't reading 'line by line'. Thanks for any help you might offer!

Update: It works ok without the extra specifiers if i just do for my $line (split/\n/, $s)

But wondering why.

[jwkrahn]

It also works like this:

for my $line ( split /^/, $s )

[haukex]

Athanasius and AnomalousMonk already explained the issue. I just wanted to add: The most performant way is the following; it avoids splitting the lines into a list first.

use warnings;
use strict;

my $s = <<'EOF';
int t; //variable t
t->a=0;  //t->a does;; something
printf("\nEnter the Employee ID : ");
scanf("%d", ptrx->eid);  //employee id ptrx->eid
printf("\nEnter the Employee Name : ");
scanf("%s", ptr->name);
return 0;
EOF

open my $fh, '<', \$s or die $!;
while ( my $line = <$fh> ) {
    chomp($line);
    print "<$line>\n";
}
close $fh;

[Athanasius]

Hello Cristoforo,

Within the look-ahead assertion (?=$), the metacharacter $ means:

Match the end of the string (or before newline at the end of the string; or before any newline if /m is used) (from “Metacharacters” in perlre#The-Basics)

Since it comes after the newline within the regex pattern — and your string contains no consecutive newlines — it can match only at the very end of the string. This explains the behaviour you’re seeing.

If you remove the look-ahead:

for my $line (split/(?m)\n/, $s) {

the output is displayed line-by-line, as expected.

Hope that helps,

[AnomalousMonk]

I disagree slightly with your narrative. A split pattern of  /(?m)\n(?=$)/ will split on any newline that is followed immediately by a newline (i.e., consequtive newlines) or on a newline at the end of the string (producing an empty string). This can be seen to be happening with modified text (and with a split LIMIT of -1 to preserve trailing null fields):

c:\@Work\Perl\monks>perl
use strict;
use warnings;
use feature 'say';

my $s = <<'EOF';
int t; //variable t
t->a=0;  //t->a does;; something

printf("\nEnter the Employee Name : ");
scanf("%s", ptr->name);
return 0;
EOF

for my $line (split/(?m)\n(?=$)/, $s, -1) {
    say '<' . $line . '>', "\n";
}

__END__
<int t; //variable t
t->a=0;  //t->a does;; something>

<
printf("\nEnter the Employee Name : ");
scanf("%s", ptr->name);
return 0;>

<>

I agree that the simplest and best approach is to split on what the OPer wants to split on, i.e., newlines, and forget about the  /m modifier and everything else.