Re: executing perl command from a perl file

[haukex]

How to execute perl -F, -lanE 'm/module/?say:say qq|.$F[0]($F[0])$F[1]|' < trial1.txt

In your thread To repeat each word in a line, where you were given this code, kcott and AnomalousMonk both gave you some example code that included while loops. The code 'm/module/?say:say qq|.$F[0]($F[0])$F[1]|' is what would go in the body of the loop, plus the code provided by the -F, -lan switches, which you can see by adding -MO=Deparse:

$ perl -MO=Deparse -F, -lanE 'm/module/?say:say qq|.$F[0]($F[0])$F[1]|
+'
BEGIN { $/ = "\n"; $\ = "\n"; }
use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'postderef_qq
+', 'say', 'state', 'switch', 'unicode_strings', 'unicode_eval';
LINE: while (defined($_ = readline ARGV)) {
    chomp $_;
    our @F = split(/,/u, $_, 0);
    /module/u ? say($_) : say(".$F[0]($F[0])$F[1]");
}

This can be cleaned up to:

use warnings;
use strict;
use feature 'say';

while ( my $line = <> ) {
    chomp $line;
    my @F = split /,/, $line;
    if ( $line =~ /module/ ) {
        say $line;
    }
    else {
        say ".$F[0]($F[0])$F[1]";
    }
}

Though you probably want to replace the <> with a filehandle from an opened file, as has been shown to you.