note
choroba
As usually, if speed is your concern, you can trade it for space.
<c>
#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };
warn "start\n";
my $tstart1 = time;
my (%by_count, %by_word);
while (<>) {
chomp;
my ($k, $v) = split /\t/, $_, 2;
if (exists $by_word{$k}) {
$v += $by_word{$k};
delete $by_count{ $by_word{$k} }{$k};
}
undef $by_count{$v}{$k};
$by_word{$k} = $v;
}
my $tend1 = time;
warn "get properties: ", $tend1 - $tstart1, " secs\n";
my $tstart2 = time;
for my $count (sort { $b <=> $a } keys %by_count) {
say "$_\t$count" for sort keys %{ $by_count{$count} };
}
my $tend2 = time;
warn "sort + output: ", $tend2 - $tstart2, " secs\n";
warn "total: ", $tend2 - $tstart1, " secs\n";
</c><P>
Comparison?
<c>
llil start
get_properties : 13 secs
sort + output : 85 secs
total : 98 secs
start
get properties: 21 secs
sort + output: 25 secs
total: 46 secs
</c>
The output is identical.<P>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-832495">
<c>map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]</c>
</div></div><!-- Wiki2Monks {"version":1.161} -->
11148465
11148465