Handling reconnection with Mail::IMAPClient

[Discipulus]

Hello folks,

I'm using Mail::IMAPClient to write my own mail monitor and currently trying handling connection problems, simulated simply detaching the ethernet cable. Ideally I'd like the program to retry a connection for some times before giving definitevely up.

With both intuitive solution like $imap->connect() if $imap->IsUnconnected and also reinstanciating the whole $imap object ( new calls connect or login on its own) I get a nasty loop of: Lost connection to ... retry 1 retry 2.. [I plug eth] Succesfully reconnected .. Lost connection to ..

Here the code reduced to the minimum (I left the read password echo(0) to play nicely with your terminal security ;)

use strict;
use warnings;

use Mail::IMAPClient;
use Term::ReadKey;

my $user   = '[e-mail]';
my $server = 'email.example.com';
my $port   = 993;
my $ssl    = 1;                # generally ssl is used
my $imap_folder = "INBOX";
my $sleep  = 5;


print "\n(use CTRL-C to permit logout)\n";
print "Enter the password for $user on $server\n";
my $password;
ReadMode('noecho');
$password = ReadLine(0);
chomp $password;
ReadMode 'normal';

my $imap = Mail::IMAPClient->new(
  Server => $server,
  User => $user,
  password => $password,
  Port => $port,
  Ssl=> $ssl,
  Uid=> 1,
  ) or die "IMAP Failure: $@";

print "Logged in succesfully\n" if $imap->IsConnected();
 
# Handle Ctrl-C
$SIG{INT} = sub{ 
    print "\n\nLogging out..\n";
    $imap->logout();
    exit;
};

# do NOT mark as read when handling messages
$imap->Peek(1);

# look in INBOX
$imap->select( $imap_folder ) or die "IMAP Select Error for imap folde
+r [$imap_folder]: $@";

my $now = time;
my %seen = map { $_ => 1} $imap->sentsince($now);

while (1){
    ##################################################################
+##############
    #        Handling a lost connection
    ##################################################################
+##############
    if ( $imap->IsUnconnected ){
        print "Lost connection to $server\n";
        for (1..100){
            sleep 1 for 1..5;
            print "Connection retry $_..\n";
            
            # option 1
            # enters in a loop connected / unconnected
            # $imap->connect();
            
            # option 2 
            # also this enters in a loop

            $imap = Mail::IMAPClient->new(
                Server => $server,
                User => $user,
                password => $password,
                Port => $port,
                Ssl=> $ssl,
                Uid=> 1,
            );
            next unless $imap;
            last if $imap->IsConnected();
        }
        # give up..
        die "Reconnection impossible!" if $imap->IsUnconnected();
        # if here we succeded
        print "Succesfully reconnected!\n";
    }
    # as the above solutions do not work..
    next if $imap->IsUnconnected();
    ##################################################################
+##############

    my @msgs = $imap->sentsince($now);
    foreach my $msg (@msgs){
        # without this line I get an undef $msg entry in %seen
        next unless defined $msg;
        next if $seen{$msg};        
        $seen{ $msg }++;        
        print "New message: ",
                $imap->get_header( $msg, "Subject" ), " from: ", 
                $imap->get_header( $msg, "From" ),"\n";    
    }    
    sleep 1 for 1..$sleep;
    $now = time;
}

Some idea on how reconnect safely and really?

L*

[markong]

You end up in an infinite loop (even upon re-connection) because you have not a break statement condition for the outer loop: try to add one last statement after print "Succesfully reconnected!\n";.

EDIT:

I've lost a chunk of code while copy/pasting: it is the case then that after sleeping your connection goes down again (maybe is the server which close the connection?). You have to dig deeper and debug/print the status of the connection after re-connection to see why it goes down.

I'd also recommend to refactor the entire thing in smaller subroutines in order to better handle the overall logic.

Test also if this parameter can already help you out with disconnections/re-connections.


Saluti

[Discipulus]

Hello markong,

thanks! even more useful is the reconnect method I totally missed from the module documentation.

As the module Carp::cluck on error issuing imap commands, then the $imap->noop seems to be a sane command to try.

The following code acts as expected and reconnect to the imap server:

while (1){
    my $attempts = 1;
    my $max_attempts = 10;
    while ( !$imap->noop ){
        print "Reconection retry $attempts..\n";
        $imap->reconnect;
        if( $imap->IsConnected() ){
            print "Reconnected succesfully!\n";
            last;
        }
        else{
            sleep 1;
            die "Impossible to reconnect: $@" if $attempts == $max_att
+empts;
            $attempts++;            
        }
    }
    print "IMAP connected\n" if $imap->IsConnected();
}

L*

PS January 31: see the definitive program

[rizzo]

Hi Discipulus

I'm using Mail::IMAPClient to write my own mail monitor and currently trying handling connection problems ...

To me this sounds as if you were trying to implement smtp server logic using an Imap client. Why not simply install a smtp server(opensmtpd, qmail, postfix) locally and then access it using Imap?

[Discipulus]

Hello rizzo and thanks for reading,

I have probably poorly expressed my question, but no: I'm not trying to implement a server logic. I'm implementing a client that connect to an IMAP server, fetches for new messages and (in the full version of the program) applies some rule to incoming messages. It is a similar behaviour to any email client programs like Thunderbird for example.

When I speak about connection problems I mean client connection problems, infact I naively simulated such problem disconnecting the ethernet cable of my pc where my perl imap client is running.

The above code shows my problem: the client provided by Mail::IMAPClient seems unbale to restablish the connection after reaching the IsDisconnected state. I'd like to recover the connection to the server instead of barely exiting the perl imap client program.

L*

[afoken]

I have probably poorly expressed my question, but no: I'm not trying to implement a server logic. I'm implementing a client that connect to an IMAP server, fetches for new messages and (in the full version of the program) applies some rule to incoming messages.

That sounds like server-side filters (e.g. Sieve = RFC3028, exim filter) moved to the client.

Alexander

[rizzo]

Sorry, my bad. Instead of simply writing about "smtp server logic", I should have been more explicit.

As far as I understand it, the smtp protocol was designed with that sort of connection problems in mind. If mails cannot be delivered instantly they stay in the queue and are sent when the remote mail server is available again. At least to me that seems a convenient solution for the connection problem.

My idea was to install an additional smtp server locally and relay the mail to the remote smtp server, that finally ends up in the IMAP server your are trying to access to that local smtp server. If accessing that mail via IMAP is desired an additional IMAP server would be necessary.

Probably to much effort if there are only a handful of mailboxes, I see that. It must have been the term "connection problem" that triggered me ;-)