Perl try { } catch(e) { }

[Superfox il Volpone]

Hi there,
I am looking for a way to implement the construct:

try {
  die ("Hello world");
} catch(e) { 
  print("Exception: " $e);
}

I know this snippet from Programming Perl 4th ed,pp 329, and it works using locals:

sub try(&$) {
  my ($try, $catch) = @_;
  eval { # perl try
    &$try
  }; if($@){ # perl catch
    local $_ = $@;
    &$catch();
  }
}
sub catch(&){  $_[0]; }

And this works as try { ... } catch { print("Exception caught: $_"); };
I'd like to refer the exception with something like catch(e){ ... }.

I would prefer to avoid using any external module such as TryCatch for portability reasons.

Thanks
s.fox

[Corion]

Have you looked at how Try::Tiny does its thing. Most likely, you can reuse that code for your implementation.

Note that catch(e) is invalid syntax in Perl (unless you declare a parameterless function e()). Resorting to something like catch  my $e { is not allowed by Perl syntax either, because the & prototype works its syntactical magic only when it is the first prototype character.

You could use something like

catch { my $e= $@;
    ...
}

... if you really want to rename $@.

[Superfox il Volpone]

Aaaaahh I think I understood now how this is supposed to work:

#!/usr/bin/env perl


sub try(&$) {
  my ($try, $catch) = @_;
  
  eval { # perl try
    &$try
  }; if($@){ # perl catch
    &$catch($@);
  }
}
sub catch(&){ shift }

try{
  die("Frankie");
} catch {
  my $e = shift;
  print("Hello world $e\n");
}

catch { ... } is invoked before the block in the try { ...}, and all it does is to return the block as a reference to the anonymous function defined by the catch block.
Tricky mechanism.

Thanks,
s.fox

[Anonymous Monk]

If you're going to use that code instead of Try::Tiny (which by the way is pure Perl and has no non-core dependencies), make sure you read the "Background" section of Try::Tiny's docs, as there are a number of issues with $@!

[karlgoethebier]

"Aaaaahh I think I understood ..."

I don't (for the moment) - but i don't care about and just do:

#!/usr/bin/env perl

use strict;
use warnings;
use Try::Tiny;

try {
    die qq(Goodbye World!);
}
catch {
    warn $_;
};

__END__

Best regards, Karl

[Anonymous Monk]

"... for portability reasons."

Welcome to the 21st Century, where that is no longer a valid excuse. Add the appropriate package to your deploy policy and let your configuration management solution do the rest.

You do have a configuration management solution, don't you? ;)