Re: Descending a directory tree, returning a list of files

Since you've used a bareword directory handle, you clobber your existing handle every time you descend a level. Never use bareword handles for recursive calls. Problem solved if you use a lexical/indirect handle:

use strict;
use warnings;
use Cwd 'getcwd';

## cwd  
my $cwd = getcwd; 

## Get files from cwd 
my $res = _list_files($cwd);

sub _list_files {

        my $dir = shift;
        my $files = shift;

        opendir(my $dh, $dir) || die "Error opening: $dir\n";

        while (my $fn = readdir($dh)) {

                ## skip hidden
                next if $fn =~ /^\./;

                ## file, fullpath name
                my $file = $dir . "/" . $fn;

                ## add
                push(@{ $files }, $file); 

                ## dir, decend
                if (-d $file) {

                        ## sub-directory files
                        $files = _list_files($file, $files);
                }
        }

        #closedir($dh); # Not necessary; auto-closed on end of scope

        return $files;
}
[download]

#11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

Comment on Re: Descending a directory tree, returning a list of files Download Code

Replies are listed 'Best First'.
Re^2: Descending a directory tree, returning a list of files by Rodster001 (Pilgrim) on Jun 09, 2015 at 20:22 UTC
That was it. Bareword directory handle. For some reason I thought that was private to that sub routine. Thank you!	[reply]
Re^3: Descending a directory tree, returning a list of files by kennethk (Abbot) on Jun 09, 2015 at 21:32 UTC
Forgetting that bareword handles are global is a common issue, which is why (for me at least) Bareword Handles Considered Harmful. #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.	[reply]
Re^4: Descending a directory tree, returning a list of files by Rodster001 (Pilgrim) on Jun 09, 2015 at 22:55 UTC
They are now officially a thing of the past. I'll never use em' again :)	[reply]


Keep It Simple, Stupid
	PerlMonks