Re: Custom, Reusable Sort Subroutine for Hashes?

[choroba]

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

sub sort_hash (&\%) {
    my ($sub, $hash) = @_;
    sort {
        local($a, $b) = @$hash{$a, $b};
        $sub->()
    } keys %$hash
}

my %hash = ( second => 2, fourth => 4, third => 3, first => 1 );
say for sort_hash { $a <=> $b } %hash;

I used a prototype to make the syntax of sort_hash similar to that of sort. The trick is replacing the magical variables $a and $b with the respective values from the hash.

Update: explanation added.

[QM]

This is very good, thanks.

Just as an extension, can I use this with a named sort sub? I expect so, but I'll have to go off and experiment.

[choroba]

> can I use this with a named sort sub?

Sure, but you can't use the nice syntax anymore:

sub numerically { $a <=> $b }
say for sort_hash(\&numerically, %hash);

[LanX]

> but you can't use the nice syntax anymore:

> say for sort_hash(\&numerically, %hash);

well you don't need the braces

say for sort_hash \&numerically, %hash ;

and this works too

say for sort_hash {numerically} %hash ;