print a file from Bottom to Top (reverse order)

[theravadamonk]

Hi, Monks, I want to know how to print a file from Bottom to Top (reverse order).

I found this below link with below code

https://www.perlmonks.org/?node_id=361397

open(FILE, "<myfile.txt");
@file = reverse <FILE>;
foreach (@file) {
    #process line
}

Given below is My CODE with while loop, I want to go with while loop. How can I print from Bottom to Top ?

How can I insert reverse order in to while loop?

What's the easiest way ? I DO hope U monks will come with ideas...

#!/usr/bin/perl
use CGI ':standard';
use strict;
use warnings;
use CGI::Carp 'fatalsToBrowser'; # use only for testing

#my $date = localtime();

$ENV{"PATH"} = "/usr/sbin:/usr/bin:/sbin:/bin";

open FILE, '<', '/var/log/maillog' or die $!;

while (<FILE>){
   chomp;
   next unless /\S/; # skip blank lines
   if (/Passed CLEAN/) { #search string Passed CLEAN
      print "$_ \n"; # print ALL lines containing Passed CLEAN

   }
}

close FILE;

[haukex]

See File::ReadBackwards:

use warnings;
use strict;
use File::ReadBackwards;

my $bw = File::ReadBackwards->new('/var/log/maillog') or die $!;
while (defined( my $line = $bw->readline )) {
    chomp($line);
    print "<$line>\n";
}
$bw->close;

[thanos1983]

Hello theravadamonk,

You can read this Is there a way to read a file backwards? or this How do I read a file line by line in reverse order (from EOF to start of file) previously asked question(s) they contain different answers to your problem.

Hope this helps, BR.

[Laurent_R]

I want to go with while loop.

Why? Given what you're doing in your second code sample, you could do it as well on the items of the @file array in your first code sample.

For example:

open(FILE, "<myfile.txt");
@file = reverse <FILE>;
foreach (@file) {
   chomp;                              # --> Note: no need to chomp, i
+t just forces you to add the \n again when you print
   next unless /\S/; # skip blank lines  --> Note: this is useless giv
+en that you print only line matching the /Passed CLEAN/ pattern
   if (/Passed CLEAN/) { #search string Passed CLEAN
      print "$_ \n"; # print ALL lines containing Passed CLEAN

   }
}

Or, simplifying a bit the syntax:

open(FILE, "<myfile.txt");
@file = reverse <FILE>;
foreach (@file) {
   print if /Passed CLEAN/;
}

That should work fine unless your file is truly huge and won't fit into memory. If your file is too big, then the File::ReadBackwards is the only simple solution;

[theravadamonk]

Thank you very much for your code. it works as expected. my file is actually maillog file. It's sometimes huge. So File::ReadBackwards is much better. But, the problem is I am trying to insert below lines in to that code.

if (/Passed CLEAN/) { #search string Passed CLEAN
      print "$_ \n"; # print ALL lines containing Passed CLEAN

   }

But, still no success. I am learning perl. I am still a novice. I googled how to insert it, But, still not lucky.

[Laurent_R]

Changing just a couple of small things to haukex's solution above should give you what you need:

use warnings;
use strict;
use File::ReadBackwards;

my $bw = File::ReadBackwards->new('/var/log/maillog') or die $!;
while (defined( my $line = $bw->readline )) {
    print $line if $line =~ /Passed CLEAN/;
}
$bw->close;

[AnomalousMonk]

Given Laurent_R's comprehensive reply, let's move on to the next question: How do I match one or more arbitrary whitespace characters between the  'Passed' and the  'CLEAN' in the pattern match? Please see the  + quantifier in perlre, and  \s in perlre and Whitespace in perlrecharclass. In general, please see perlretut.

[afoken]

tac

Alexander