How do I make a hash of arrays?

Answer: How do I make a hash of arrays?
contributed by chromatic

my %dramatis_personae = (
    humans => [ 'hamnet', 'shakespeare', 'robyn', ],
    faeries => [ 'oberon', 'titania', 'puck', ],
    other => [ 'morpheus, lord of dreams' ],
);
[download]

Access it like this:

foreach my $group (keys %dramatis_personae) {
    print "The members of $group are\n";
    foreach (@{$dramatis_personae{$group}}) {
        print "\t$_\n";
    }
}
[download]

Answer: How do I make a hash of arrays?
contributed by Anonymous Monk

You can always...

push(@{$hash{$key}}, $insert_val);
[download]

...to load the arrays in the hash. That way you don't have to build the arrays, then dereference them into the hash.

Answer: How do I make a hash of arrays?
contributed by Anonymous Monk

my @arrayOne = 1..10;
my @arrayTwo = 20..30;
my %HashOfArrays = ( one => \@arrayOne );
$HashOfArrays{two} = \@arrayTwo;
$HashOfArrays{IpointToTheSameArrayAsOne} = \@arrayOne ;
$HashOfArrays{IreferenceTheSameArrayAsOne} = \@arrayOne ;
$HashOfArrays{MyValueIsThatOfOneAsWell} = \@arrayOne ;
[download]

## to create an array reference, just type \@array
## or [ @array ]
##  [ @array ] does not equal \@array
## see perlref for more info

Answer: How do I make a hash of arrays?
contributed by Doraemon

my $array = [];    #create new anonymous array ref
push (@$array, '11');
push (@$array, '12');
push (@$array, '13');
$hash{'first'} = $array;   # add

$array = [];   #create a new anon-array
push (@$array, '21');
push (@$array, '22');
push (@$array, '23');
$hash{'second'} = $array;  # add

print "Hash content\n";
foreach $k (keys %hash) {
   foreach (@{$hash{$k}}) {
      print " : $_";
   }
   print "\n";
}
[download]


Clear questions and runnable code get the best and fastest answer
	PerlMonks