How can I call subroutines in an array

[ozgurp]

use strict;
use warnings;

my @procs;


sub a1 {
    print("a1\n");
}

sub a2 {
    print("a2\n");
}


@procs = (&a1, &a2);

foreach (@procs) {
    $_;
}

This code gives the following message

"Useless use of a variable in void context at C:\test.pl line 19."

what is the better way of doing this?

[Chmrr]

It's hard to tell, but you're calling them when you think you're putting them into the array -- that is, at the @procs = (&a1, &a2) line. The solution to this problem is references, as discussed in perlref and perlreftut. As follows:

use strict;
use warnings;

sub a1 {
  print("a1\n");
}

sub a2 {
  print("a2\n");
}

my @procs = (\&a1, \&a2);

foreach (@procs) {
    $_->();
}

perl -pe '"I lo*`+$^X$\"$]!$/"=~m%(.*)%s;$_=$1;y^`+*^e v^#$&V"+@( NO CARRIER'

[dvergin]

How's this:

use strict;
use warnings;

sub a1 { print("a1\n"); }
sub a2 { print("a2\n"); }

my @procs = (\&a1, \&a2);

foreach (@procs) {
    &$_;
}

# or for a more idiomatic approach
# enter anonymous subs directly into the array:

my @procs2 = (sub { print("this\n") },
              sub { print("that\n") }
             );

foreach (@procs2) {
    $_->();        # alternate form to call subroutine ref
}

All of which prints:

    a1
    a2
    this
    that


------------------------------------------------------------
"Perl is a mess and that's good because the
problem space is also a mess." - Larry Wall

[eyepopslikeamosquito]

Slightly different approach. Hey, variety is the spice of life!

use strict;
use warnings;

sub Handler::a1 {
  print("a1\n");
}

sub Handler::a2 {
  print("a2\n");
}

for (1..3) {
  exists($Handler::{'a'.$_}) ? &{$Handler::{'a'.$_}} :
     print "no handler for $_\n";
}