Drop middle part in a substitution

[James LiGate]

I suspect this is a dead-simple Perl newbie question (and I'm a dead-simple Perl newbie! :o) ), but darned if I can work it out. I need to process filenames in the format filename.randomcharsEXT where EXT is a three-letter extension of any case (e.g., gif, Jpg, TXT...) and randomchars is guaranteed not to contain a period or any "special" characters. For an input of filename.randomcharsEXT the output needs to be filename.EXT... in other words, I need to drop the random characters between the dot and the extension. This would be straightforward to do across multiple statements, but I'm thinking I should be able to do it with a single s/// and some thoughtful RE. Darned if I can noodle out the syntax, though. Can anyone point me to some references or examples? Nothing I've found in my search so far has helped. Thanks!

[Roy Johnson]

s/^(.*\.).*(...)$/$1$2/
Update:
No need to fiddle with capturing and replacing. Just strip out the stuff we don't want:
s/[^.]+(?=...$)//

[James LiGate]

"Most magic tricks are easy, once YOU know the secret." -- Marshall Brodien

Gah! In studying your substitution, it's immediately obvious how it works... but crafting it from scratch was simply beyond me. I guess I just don't "have my head around Perl" yet... but I'll get there eventually, I hope.

A code snippet that I can just plug in is way more than I was expecting; thank you!

[!1]

Not to be picky but you are aware that newlines are valid in filenames under some OS's, right?

s/^(\.*\.).*(...)$/$1$2/s;

Of course, two periods within a filename may also throw this off.

Update: Ok. You all got me. I'm a dipshit. Thanks.

[Not_a_Number]

s/^(\.*\.).*(...)$/$1$2/s;

This doesn't work for me:

$_ = 'filename.12345Gif';
s/^(\.*\.).*(...)$/$1$2/s;
print;

Output:

filename.12345Gif

Drop that first backslash :)

s/^(.*\.).*(...)$/$1$2/s;

dave

[Roy Johnson]

Two periods should not throw it off: the characters to be discarded were guaranteed not to include any periods, so the greedy match is appropriate.

As for newlines in filenames: I definitely didn't think of that.

[ambrus]

AFAIK msdos fat is the only filesystem with 8.3 filenames. But fat does not allow a newline (in fact it allows only very few characters, and definitly no control characters but \x7f.)

[ysth]

Not to be picky but you are aware that newlines are valid in filenames under some OS's, right? :)

If the filename ends with a newline, you'll end up keeping the last 4 characters instead of the last three. Try:

s/^(.*\.).*(...)\z/$1$2/s;

instead.

[Abigail-II]

    s/[.][^.]*(...)$/.$1/;

Abigail

[borisz]

  s/[^\.]*(?=(?:jpg|gif|txt)$)//;

[Not_a_Number]

TMTOWTDI. Here's a non-regex solution:

my $name = 'filename.dqhfhqlkGif';
substr $name, (index $name, '.') + 1, -3, '';
print $name;

In fact if you change index to rindex, it'll work even if there's more than one period in the name.

dave

Update: Also works with filenames containing newlines.