I basically agree :-) There are certainly other useful styles for setters. For example, the idiom of returning the old value in a setter allows you to compact:

my $old = $foo->fribble
$foo->fribble($new);
... do something ...
$foo->fribble($old);
[download]

to

my $old = $foo->fribble($new)
... do something;
$foo->fribble($old);
[download]

However, for me the extra clutter that C::P::MC adds takes away the advantages that chaining gives you :-)

That said - how about this as a way to get around the name clashing problems:

package Class::Chain;
use strict;
use warnings;

sub AUTOLOAD {
    my $self = shift;
    our $AUTOLOAD;
    my ($method) = ($AUTOLOAD =~ m/^.*::(.*)$/);
    return bless \$self->$method(@_) unless ref($self);
    return $$self->$1(@_) if $method =~ m/^raw_(.*)$/;
    return bless \$$self->$1(@_) if $method =~ m/^wrap_(.*)$/;
    $$self->$method(@_);
    return($self);
};

sub chain {
    my ($self, $sub) = @_;
    $sub->($self);
    $self;
};

sub DESTROY {};
[download]

Which gives you:

# call the whatever method and return $wrapped
$wrapped->whatever

# call the whatever method and return any value(s)
$wrapped->raw_whatever

# call the underlying method and wrap return value
$wrapped->wrap_whatever

# run $wrapped->$coderef and return $wrapped
$wrapped->chain($coderef)
[download]

So your second example would become something like (untested):

my $file_dialog = Gtk::FileSelection
   ->Class::Chain::new("File Selection Demo")
   ->chain(sub {shift->wrap_ok_button
       ->label("Load")
       ->relief("half")
       ->width(80)
       ->height(50)
       ->signal_connect(clicked => sub {
           print $file_dialog->get_filename()->ret_val, "\n";
       });
   })
   ->chain(sub {shift->wrap_cancel_button
       ->label("Exit")
       ->relief("half")
       ->width(80)
       ->height(50)
       ->signal_connect(clicked => sub{Gtk->main_quit});
   })
   ->set_filename("penguin.png")
   ->signal_connect(destroy => sub{Gtk->main_quit})
   ->show();
[download]

I still think it's ugly tho :-) :-)