Whoops. This is what I get for coding after my brain has already shut down for nightly maintenance.

Those quick_accept and quick_reject routines will give false rejections with longitudes near the 180 degree longitude. (not an issue with US locations, I know, but...) Also, there's a stupid bit of time-wasting going on near the top there.

Let's see if I can get it right this time:

sub make_quick_reject {
  # Args: lat (radians), long (radians), dist
  my($lat,$long,$dist) = @_;
  my($maxlatdiff) = $dist / EARTH_RADIUS;
  if (abs($lat) + $maxlatdiff > PI/2) {
    # special case - near poles
    return sub { abs($lat - $_[0]) > $maxlatdiff; };
  }
  my($longmult);
  $longmult = 1 / cos(abs($lat) + $maxlatdiff);
  my($maxlongdiff) = $maxlatdiff * $longmult;
  return sub { abs($lat - $_[0]) > $maxlatdiff or 
               ( abs($long - $_[1]) > $maxlongdiff and
                 abs($long - $_[1]) < 2*PI - $maxlongdiff ); };
}

sub make_quick_accept {
  # Args: lat (radians), long (radians), dist
  my($lat,$long,$dist) = @_;
  my($maxlatdiff) = $dist / EARTH_RADIUS;
  $maxlatdiff /= sqrt(2);
  my($longmult);
  if (abs($lat) < $maxlatdiff ) {
    # special case - near equator
    $longmult = 1;
  } else {
    $longmult = 1 / cos(abs($lat) - $maxlatdiff);
  }
  my($maxlongdiff) = $maxlatdiff * $longmult;
  return sub { abs($lat - $_[0]) < $maxlatdiff and 
               ( abs($long - $_[1]) < $maxlongdiff or
                 abs($long - $_[1]) > 2*PI - $maxlongdiff ); };
}
[download]

And just again as a reminder, the sub's produced by these two routines accept longitudes and latitudes in RADIANS, not degrees. (Though reworking them to use degrees instead of radians should not be difficult at all)

And if anyone uses this code without understanding how it works, they deserve what they get. No warranty of anything useful implied at all; the code may not even pass perl -c.