Sorting hash values

[K_M_McMahon]

Hello fellow Monks. I am sure there is a simple (and obvious) answer to this question that I am just overlooking. Thanx for any help you can give me would be great!

I threw together a script to scan through my linux message log to track the failed login attempts. I was trying to see which IP addresses were responsible for most of the attempts. (also which usernames were tried multiple times). I created a hash to store the IP address as the key and the times found as the count. How do I get the results sorted by frequency. I don't know how to sort by the value, and I can't make the count the key because it is not unique.

I tried pushing the result strings into an array which I can sort if the number is first, but that failed to sort properly since I can't use {$a<=>$b} because of the text!

#!/usr/bin/perl -w
use strict;
my ($attempt,$failed)=(0,0);
my (%ip,%usr);
opendir(TEMP,'.') or die "I can't open the current directory.\n";
my @files=grep(/^messages/,readdir(TEMP));
closedir(TEMP);
foreach my $file (@files)
    {
    print "Found $file\n";
    &check($file);
    }
print "Found $attempt intrustion attempts.\n";    
print "Found ($failed) failed matches.\n";
foreach my $key (keys(%ip))
    {
    print "Found $ip{$key} attempts from $key\n";
    }
foreach my $key (keys(%usr))
    {
    print "Found $usr{$key} attempts for  $key.\n";
    }
    
            
sub check
    {
    my $file=shift;
    open(LOG,"<$file") or die "Can't open $file\n";
    while (<LOG>)
        {
        next if $_!~m/Failed/;
        $attempt++;
        my ($username,$ip_no)=$_=~/Failed .* for (?:illegal user )?(\w
++-?\w*) from ::[a-f0-9]{4}:(\d+\.\d+\.\d+\.\d+)/;
        if ((defined($username))&&(defined($ip_no)))
            {
            $ip{$ip_no}++;
            $usr{$username}++;
            }
        else {$failed++;    }
        }
    close(LOG);
    }

What obvious solution am I missing?

[davido]

You wish to sort a list of hash keys in order by the values they index. Try this:

my @ips_prioritized = sort { $ip{$a} <=> $ip{$b} } keys %ip;

[Zaxo]

You can sort the keys by value in the hash:

my @ips  = sort { $ip{$b} <=> $ip{$a} } keys %ip;
my @usrs = sort {$usr{$b} <=> $usr{$a}} keys %usr;

By comparing $b terms on the left, we get descending order.

[K_M_McMahon]

Thanx davido && zaxo, I knew it was something simple!