IF and some conditions

[uksza]

Hello Wise Monks,

Is it good way?

$test = 7;
#(OK only when $test is 7,5 or 3)

#OK, but... long
print "OK\n" if ($test == 7 or $test == 5 or $test == 3);

#NOT OK
#print "OK\n" if ($test == (7 or 5 or 3));

#OK?
print "OK\n" if ($test =~ /[753]/);

Last try is good? Rather not (what about 55, 33 etc?)
Is any good (not switch/case) method to test it?

Thanx a lot
uksza

[thcsoft]

there are a lot of ways. you proposed 3 of them, of which the last one looks the most elegant to me. but just for the sake of my vanity here's another approach:

print "OK\n" if grep /$test/, (3,5,7);

;)

[Joost]

I'd really rather write that with an == test instead of a regular expression:

print "OK\n" if grep { $test == $_ } (3,5,7);

[Joost]

You could use Quantum::Superpositions - (from the docs):

        use Quantum::Superpositions;

        if ($x == any($a, $b, $c)) { ...  }

Update: In this specific case, that would translate to:

use Quantum::Superpositions;

$test = 7;

if ($test == any(7, 5, 3)) {
        print "\$test is ",any(7, 5, 3),"\n";
}
__OUTPUT__
$test is any(3,7,5)

[wfsp]

one more

my %hash = map {$_ => undef} qw(7 5 3);
print "ok" if exists $hash{$test};

[mugwumpjism]

If you want a set, then use a set.

use Set::Object;

my $set = set(qw(7 5 3));
print "ok" if $set.includes($test);

This module is called plain "Set" in Perl 6.

[jhourcle]

#NOT OK
print "OK\n" if ($test =~ /[753]/);

I think you were on the right track with why the last one wasn't good. Try with any of the following input, and you'll see why: 50, 72, 39, 256. You want to anchor your regexes when testing for equality:

print "OK\n" if ($test =~ /^[753]$/);

Update: I can't spell.

[tlm]

Here's another solution, using first (to stop searching as soon as possible):

use List::Util 'first';
print "OK\n" if defined first { $test == $_ } (7, 5, 3);

[aukjan]

And another one


$test  = 7;
@array = qw(3 5 7);
foreach ( @array ){  print $test == $_ ? 'OK':undef;}

[Ben Win Lue]

for rather small values that are OK, this seems to be the fastest solution:

my @ok=(0,0,0,1,0,1,0,1);
#       0 1 2 3 4 5 6 7

my $x = 4;
my $y = 5;

if($ok[$x]){print "$x is ok\n";}
if($ok[$y]){print "$y is ok\n";}

if your OK-values get larger, I would use a hash instead of an array!

[nedals]

One more solution...

if ($result =~ /^(3|33|5|17)$/) { print "it's there\n"; }

[mugwumpjism]

In perl 6, Junctions are a core language feature.

So, you could write:

say "OK" if ($test == any(7,5,3));

Thankfully someone has already implemented them for Perl 5, with the module on CPAN called Perl6::Junctions;

use Perl6::Junctions qw(any);
print "OK\n" if ($test == any(7,5,3));

This is actually very similar to the Quantum::Superpositions answer above, and I believe the implementations share a common root.