easiest way to print the content of a hash?

[s_m_b]

I need to check the current content of a hash, but can't figure how to just dump the content out - similar to doing print @some_list for dumping out a list's content. I tried %some_hash and %some_hash{} with no success.

[ptum]

There's always Data::Dumper.

Or, assuming your hash values are scalars, you can step through the keys and print out the contents, like this:

  foreach (sort keys %myhash) {
    print "$_ : $myhash{$_}\n";
  }

[McDarren]

I can never quite get why nobody (apart from me) ever seems to recommend Data::Dumper::Simple for debugging?

It's way easier to use than Data::Dumper, especially for more complex data structures. There is no need to pass references, and the output contains the actual variable names - instead of "VAR1", "VAR2", etc.
I know you can get the same thing with Data::Dumper using Dumper->Dump, but this can very quickly become quite unwieldy.

About the only objection I could imagine to using Data::Dumper::Simple is that is uses source filters, but if you're only using it for debugging - and not in production code - what's the problem?

Just curious....
Darren :)

[japhy]

Perhaps because it's a source filter? (Yes, I read your post. And yes, that's my reason.)

[tinita]

There is no need to pass references, and the output contains the actual variable names - instead of "VAR1", "VAR2", etc.

it's time again to quote my .vimrc:
:imap dumper <ESC>^iwarn Data::Dumper->Dump([\<ESC>llyw$a], ['<ESC>pa']);<ESC>
let's you type '@myarraydumper' and you'll get
warn Data::Dumper->Dump([\@myarray], ['myarray']);

Data::Dumper is in the core, and with the help of my editor i don't have to type much to get a decent debugging output.

[saberworks]

use Data::Dumper;
my %hash = (
    key1 => 'value1',
    key2 => 'value2'
);

print Dumper(%hash);  # okay, but not great
print "or\n";
print Dumper(\%hash); # much better

And the output:

$VAR1 = 'key2';
$VAR2 = 'value2';
$VAR3 = 'key1';
$VAR4 = 'value1';
or
$VAR1 = {
          'key2' => 'value2',
          'key1' => 'value1'
        };

[marto]

On a related note there is Re: I've got a hash of hashes how do i get my values out, which you may find interesting.

Hope this helps.

Martin

[s_m_b]

thanks for the suggestions. data::dumper looks good to me. I've used the foreach, of course, but that's messy for a quick output.

[davido]

If you don't like the output of Data::Dumper and just want a simple key/value dump (without any deep datastructure exploration), you could apply this function:

sub print_hash {
    my $href = shift;
    print "$_\t=> $href->{$_}\n" for keys %{$href};
}

It could also be written like this:

sub print_hash {
    my $href = shift;
    while( my( $key, $val ) = each %{$href} ) {
        print "$key\t=>$val\n";
    }
}

[coreolyn]

If you're just doing a quick check on the contents of a hash nothing beats print "\%hash = @{[%hash]}\n"; for debugging.

[planetscape]

Re: How can I visualize my complex data structure? will provide an array of options for doing just this (no pun intended).

HTH,

[Anonymous Monk]

map{print "$_\t$hash{$_}\n"}keys %hash;