how to convert numbers to ASCII characters

[redss]

Hi Monks,

I want to take a series of numbers, each number between 0 and 255, and write each number to an ASCII file as a single character.

How can I write each number to the file as an ASCII character, and then convert each character back to the number when reading from the file?

[olus]

Check the chr and ord functions.

print FILE chr(78);

$number = ord('N');

[moritz]

ASCII covers only the range from 0 to 127. (And yes, chr and ord are the right builtins).

[redss]

ok that is fine if ASCII only covers 0-127. The file I write to can be a binary file rather than ascii, so will the same functions work in that case?

[lidden]

Yes, they will work. Perl uses Latin1 in the range 0..255.

[shmem]

See pack and unpack.

print FILE pack "C*", @numbers; # write
@numbers = unpack "C*", <FILE>; # read

[ikegami]

Binary files aren't likely to be LF-terminated, so <...> isn't likely to be appropriate.

sub read_block {
   my ($fh, $bytes_to_read) = @_;
   my $buf = '';
   while ($bytes_to_read) {
      my $bytes_read = read($fh, $buf, $bytes_to_read, length($buf));
      die("Unable to read from file: $!\n")
         if !defined($bytes_read);
      die("Unable to read from file: Unexpected end of file\n")
         if !$bytes_read;
      $bytes_to_read -= $bytes_read;
   }
   return $buf;
}

# Write
print $fh (pack('C',  scalar(@numbers));
print $fh (pack('C*', @numbers));

# Read
my $num_numbers = unpack('C',  read_block($fh, 1));
my @numbers     = unpack('C*', read_block($fh, $num_numbers));

Update: Fixed incorrect variable name. Thanks blokhead.

[shmem]

Binary files aren't likely to be LF-terminated, so <...> isn't likely to be appropriate.

As always, that depends. It is likely to be appropriate if the file isn't too big and read in slurp mode.

[oxone]

Watch out for this banana skin: you also need to 'binmode' your file when reading/writing it, otherwise characters with numbers 10 and 13 (used for line ends) may get messed up.

[ikegami]

There's also pack and unpack. For example,

print FILE pack('C', 78);