Relative URI

[choroba]

Dear Monks. Can anyone explain the following behaviour?

use strict;
use warnings;
use feature "say";

use URI;
my $base = URI->new("http://a.b.c/d/../e/");
my $uri = URI->new("http://a.b.c/y");
say $uri->rel($base); # ../../../y

The only explanation I can think of is that /../ are only understood in relative URI's, not in absolute ones. But why? Can you enlighten me?

[Anonymous Monk]

I don't get it, what is it you're expecting? Try

use Test::More qw' no_plan ';
...
is( $uri->rel($base), ' expect ' );

Have you seen/run http://cpansearch.perl.org/src/GAAS/URI-1.58/t/abs.t?

[ikegami]

He expects http://a.b.c/d/../e/ to be the same as http://a.b.c/e/.

use strict;
use warnings;

use Test::More tests => 1;

use URI qw( );

my $base1 = URI->new("http://a.b.c/d/../e/");
my $base2 = URI->new_abs("../e/", URI->new("http://a.b.c/d/"));
my $uri   = URI->new("http://a.b.c/y");

is($uri->rel($base1), $uri->rel($base2));

1;

1..1
not ok 1
#   Failed test at a.pl line 12.
#          got: '../../../y'
#     expected: '../y'
# Looks like you failed 1 test of 1.

I don't see anything in http://cpansearch.perl.org/src/GAAS/URI-1.58/t/abs.t that covers this case.

The equality definitely doesn't hold up in file systems (due to links both soft and hard), but ../../../y is much less likely to be correct.

Update: Improved test a bit.

[JavaFan]

He expects http://a.b.c/d/../e/ to be the same as http://a.b.c/e/.

If I read section 5.2 of RFC 3986 correctly, the OP quite rightly expects that to be.

[Anonymous Monk]

#!/usr/bin/perl --
use strict;
use warnings;
use URI;

Main( @ARGV );
exit( 0 );

sub Main {
    ABT();
}

sub ABT {
    require Test::More;
    Test::More->import(qw' no_plan ');

    my $base = URI->new("http://a/d/../e/");
    my $uri = URI->new("http://a/y");

    is( $base, ( "http://a/d/../e/" ) x 2 );
    is( $base->path, ( "/d/../e/" ) x 2 );
    is( $uri, ( "http://a/y" ) x 2 );
    is( $uri->path, ( "/y" ) x 2 );

    diag("should the following be equivalent??");

    is( $uri->rel($base), "??", q~$uri->rel($base)~ );
    is( URI->new( $uri->path )->rel( $base->path ),
        $uri->rel($base), q~URI->new( $uri->path )->rel( $base->path )
+~ );
    is( URI->new("/y")->rel("/d/../e/"),
        $uri->rel($base), q~URI->new("/y")->rel("/d/../e/") ~ );
}
__END__
ok 1 - http://a/d/../e/
ok 2 - /d/../e/
ok 3 - http://a/y
ok 4 - /y
# should the following be equivalent??
not ok 5 - $uri->rel($base)
#   Failed test '$uri->rel($base)'
#   at - line 27.
#          got: '../../../y'
#     expected: '??'
not ok 6 - URI->new( $uri->path )->rel( $base->path )
#   Failed test 'URI->new( $uri->path )->rel( $base->path )'
#   at - line 28.
#          got: '/y'
#     expected: '../../../y'
not ok 7 - URI->new("/y")->rel("/d/../e/")
#   Failed test 'URI->new("/y")->rel("/d/../e/") '
#   at - line 30.
#          got: '/y'
#     expected: '../../../y'
1..7
# Looks like you failed 3 tests of 7.

[Khen1950fx]

Using Test::URI, ../../../y seems relatively correct:

#!/usr/bin/perl

use strict;
use warnings;
use URI;

my $uri_string1 = 'http://a.b.c/d/../e/';
my $uri_string2 = 'http://a.b.c/y';

my $base = URI->new($uri_string1);
my $uri = URI->new($uri_string2);

print $base->abs($uri), "\n";
print $uri->abs($base), "\n";

print $base->rel($uri), "\n";
print $uri->rel($base), "\n";
print "\n";

use Test::URI;
use Test::More tests => 4;

use_ok( 'Test::URI' );

uri_scheme_ok( $uri_string2, 'http' );
uri_host_ok( $uri_string2, 'a.b.c' );
uri_path_ok( $uri_string2, '/y' );

[ikegami]

What do you think you're testing? Your code in no way supports your conclusion.