String Buffer

[kayos]

Category:

strings

Description:

Sometimes I encounter a script or program that wants to print directly to STDOUT (like Parse::ePerl), but I want it in a scalar variable. In those cases, I use this StringBuffer module to make a filehandle that is tied to a scalar.

Example:

use StringBuffer;
my $stdout = tie(*STDOUT,'StringBuffer');

print STDOUT 'this will magically get put in $stdout';

undef($stdout);
untie(*STDOUT);

# $Id: StringBuffer.pm,v 1.1 2000/04/03 22:53:04 kayos Exp $
package StringBuffer;


sub TIEHANDLE {
    my ($class, $c) = @_;
    return bless(\$c,$class);
}

sub PRINT {
    my ($self) = shift;
    ${$self} .= join('', @_);
}

sub PRINTF {
    my ($self) = shift;
    my ($fmt) = shift;
    ${$self} .= sprintf($fmt, @_);
}       

#   sometimes Perl wants it...
sub DESTROY { };

1;

[bruno]

Thanks a lot, I can make real use of this!

[FunkyMonk]

Or, without using tie:

open my $oldout, ">&STDOUT" or die "Can't dup STDOUT: $!";

my $stdout;
close STDOUT;
open STDOUT, ">", \$stdout or die $!; # This is where the magic happen
+s

print "foo\n";

close STDOUT;
open  STDOUT, ">&", $oldout or die $!;

print "Done fooling around\n";

print $stdout; # foo

This is mostly copy & pasted from open, so you might want to look there for more.

[ambrus]

In fact, that uses a perlio layer silently.

I've been wishing a perlio layer that allows you to simply open a stream that behaives like any tied handle eg.

use StringBuffer;
use PerlIO::Tied;
# Note: never close one of the three standard handles. It's almost alw
+ays a bad idea.
open OLDSTDOUT, ">&=STDOUT";
open STDOUT, ">:tied(StringBuffer)"; # I presume extra arguments to ti
+e get passed as extra argument to open
print STDOUT "this magically gets put to \$stdout\n";
open STDOUT, ">&=OLDSTDOUT";
print STDOUT "this gets put to the original standard output again\n";

This gets even more useful if you want to use a tied io handle from the command line eg. perl -MPerlIO::Tied -we 'some code' ':tied(SomeModule, arguments)'.