How to store arrays in another array

[kwatts59]

Hello Monks,

I am trying to store a set of arrays into a master array for later processing. In my example below, I have 5 arrays that I want to store in a master array called @rows. But when I try printing the values in @rows, it only displays the first element of each row. Any help would be appreciated.

Ken

my @row1 = qw(71 22 15 10 51);
my @row2 = qw(91 82 28 11 91);
my @row3 = qw(11 72 37 58 20);
my @row4 = qw(21 42 63 24 16);
my @row5 = qw(81 32 53 54 42);


my @rows = ();
@rows[0] = @row1;
@rows[1] = @row2;
@rows[2] = @row3;
@rows[3] = @row4;
@rows[4] = @row5;

$i = 0;
while ($i <= 4)
{
  print "@rows[$i]\n";
  $i++;
}

[Fletch]

You want to store a reference to the array. $rows[0] = \@row1; or push @rows, \@row1; for example. See perlref, perldsc, perllol.

Additionally: referencing a single element of an array with a @ sigil is (pretty much always) wrong; if you mean a single element use $foo[$idx].

[AnomalousMonk]

Slightly more concise:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @row1 = qw(71 22 15 10 51);
 my @row2 = qw(91 82 28 11 91);
 my @row3 = qw(11 72 37 58 20);
 my @row4 = qw(21 42 63 24 16);
 my @row5 = qw(81 32 53 54 42);
 ;;
 my @rows = \(@row1, @row2, @row3, @row4, @row5);
 ;;
 dd \@rows;
"
[
  [71, 22, 15, 10, 51],
  [91, 82, 28, 11, 91],
  [11, 72, 37, 58, 20],
  [21, 42, 63, 24, 16],
  [81, 32, 53, 54, 42],
]

[Bloodnok]

... or even more succinctly ...

my @rows = (
    [ qw(71 22 15 10 51) ],
    [ qw(91 82 28 11 91) ],
    [ qw(11 72 37 58 20) ],
    [ qw(21 42 63 24 16) ],
    [ qw(81 32 53 54 42) ],
);

or, if you really need to identify each array separately ...

my @row1 = qw(71 22 15 10 51);
my @row2 = qw(91 82 28 11 91);
my @row3 = qw(11 72 37 58 20);
my @row4 = qw(21 42 63 24 16);
my @row5 = qw(81 32 53 54 42);

my @rows = ( \@row1, \@row2, \@row3, \@row4, \@row5 );

[AnomalousMonk]

my @rows = ( \@row1, \@row2, \@row3, \@row4, \@row5 );

That's what
    my @rows = \(@row1, @row2, @row3, @row4, @row5);
does.

[Bloodnok]

Hmm, never knew that; TFT - just goes to show that my sig isn't in the least inaccurate