How do I do a bulk rename?

[Anonymous Monk]

I want to move xxx_yyy.zzz to xxx-yyy.zzz, but cant figure out how to automate this. Any ideas?

Originally posted as a Categorized Question.

[jjhorner]

Try this:

#!/usr/bin/perl -w

foreach (@ARGV){ 
       $name = $_ ;
       $name =~ s/_/-/;
       rename($_, $name);
       print "$_ renamed to $name\n";
 } 

usage: renamer.pl *.zzz

J. J. Horner

[Shendal]

Use File::Copy.



use File::Copy;
use strict;

my($sourcedir) = shift || die "No source dir";
opendir(DIR,"$sourcedir");
foreach (grep !/^\.\.?$/,readdir DIR) {
    if (/^(\S+)_(\S+)\.(\S+)$/) {
    if (move($_,"$1-$2.$3")) {
        print "Moved $_ to $1-$2.$3\n";
    } else {
        print "Error moving $_ to $1-$2.$3\n";
    }
    }
}

HTH,
Shendal

[kryberg]

#!/usr/bin/perl -w
# rename all files with a certain extention in a directory

use strict;

my $dirname;
$dirname = '/substitue_your_path_here';

opendir(DIR, $dirname) or die "Can't opendir $dirname: $!";

while ( defined (my $file = readdir DIR) ) {
        # ignore current and parent directory . and ..
        next if $file =~ /^\.\.?$/;
        my $new = $file;
        # substitute new file extension
        $new =~ s/\.old_extension$/\.new_extension/;
        rename($file,$new)
}

Reference Perl Cookbook Chapter 9 and Programming Perl Chapter 29

[fundflow]

You can use Rename files safely which will make sure that no files are erased in the process.