Variable as module name?

[Cody Fendant]

I want to do this:

use Foo;
my $object = Foo->new();

Only I want to replace 'Foo' with a variable determined by some other factor.

my $module_name = 'Foo';
use $module_name;
my $object = $module_name->new();

I got as far as understanding that use will never be happy with this, is that right? And I ought to use require instead?

My code doesn't give an error if I do this:

$module = 'Foo';
my $module_path = $module . '.pm';
require $module_path;

But it complains that I'm calling "new" on an unblessed reference when I do my $object = $module->new(); on the next line.

[kennethk]

You cannot use use in this context because it is wrapped in an implicit BEGIN block (see BEGIN, UNITCHECK, CHECK, INIT and END), and thus gets evaluated at compile time and before you could initialize the value of your variable. The usual work around here is to use a string eval, a la:

my $module_name = 'Foo';
eval "use $module_name;1;" or die "Couldn't use $module_name: $@";

Of course, this has security implications, since you are evaluating arbitrary code, depending on where your value comes from.

But it complains that I'm calling "new" on an unblessed reference when I do my $object = $module->new(); on the next line.

This should not be happening. The following code works for me (assuming an OO-module Foo in your path):

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my $module = 'Foo';
my $module_path = "$module.pm";
$module_path =~ s|::|/|g;
require $module_path;

print Dumper $module->new;

Note the s|::|/|g to allow non-root modules. Also note that by requiring you are bypassing the import mechanism.

[Anonymous Monk]

use Module::Load; load $module;

[Cody Fendant]

Thank you very much, that's all working fine now. My unblessed reference problem was an unrelated error in my module.

[Anonymous Monk]

Module::Pluggable, if

stupid pet tricks :)

$ perl -we " use if eval{require CGI}, our $cgi = 'CGI'; print $cgi->n
+ew->header "
Content-Type: text/html; charset=ISO-8859-1