Re^2: Mojo: non-blocking API calls

[Beatnik]

Pseudo code would be something like:

sub save
{ my $self = shift;
  my $acs = Net::Cisco::ACS->new("hostname"=>"localhost");
  my $user = Net::Cisco::ACS::User->new("username"=>"foobar");
 $acs->create($user); # Blocking code
 # Calling create will take a few seconds
}

sub list 
{ my $self = shift;
  my $acs = Net::Cisco::ACS->new("hostname" => "localhost");
  my %users = $acs->users; # Blocking code
  # Calling users will take a few seconds
}

I don't need to call the API at that specific time. My original approach was to flag the record in my local database as 'created' or 'modified' and run a background process to make sure the local database synchronizes all flagged records with the application using the API. The list method would then only read from the database and make adjustments in the database.

[stevieb]

Perhaps something as simple as forking is all you need. Here's an example that kind of simulates what I think you're trying to do. Essentially, we create an API object with a couple of methods. Instead of calling them directly, we pass the object and the sub we want to call on it to a forking routine from within a local sub (save(), users()), and then let it work in the background while the main script carries on.

At the end of the script, we wait until all forked processes have completed before we exit.

use warnings;
use strict;

package Thing; {
    sub new {
        return bless {}, shift;
    }
    sub users {
        print "in ". __PACKAGE__ . " execing users()\n";
        sleep 2; # simulate long API call
        print "done API users()\n";
    }
    sub save {
        print "in ". __PACKAGE__ . " execing save()\n";
        sleep 2; # simulate long API call
        print "done API save()\n";
    }
}

package main;

use Parallel::ForkManager;

my $max_forks = 10;

my $fork = new Parallel::ForkManager($max_forks);
my $api = Thing->new;

print "doing stuff in main...\n";
print "calling main::save()...\n";

save($api);

print "continuing in main, save() API call isn't blocking\n";

print "calling main::users()...\n";

users($api);

print "finished in main, waiting for forks to finish\n";

$fork->wait_all_children;


sub save {
    my $api = shift;
    fork_api_call($api, 'save');
    print "forked API save...\n";
}
sub users {
    my $api = shift;
    fork_api_call($api, 'users');
    print "forked API users...\n";
}
sub fork_api_call {
    my ($api, $sub) = @_;

    for (0..$max_forks){
        $fork->start and last;
        $api->$sub();
        $fork->finish;
    }
}

Output:

doing stuff in main...
calling main::save()...
forked API save...
continuing in main, save() API call isn't blocking
calling main::users()...
in Thing execing save()
forked API users...
finished in main, waiting for forks to finish
in Thing execing users()
done API save()
done API users()